Descrição:Este Ponto de Entrada é executado ao clicar no botão Finalizar Venda dentro da tela de registro de itens, tem o objetivo de validar os itens lançados na venda antes de entrar na tela de pagamento.
Programa fonte:STIItemRegister.prw
Função:StCallPay
Parâmetros:

PARAMIXB[1]: Código do cliente que foi selecionado na venda.

PARAMIXB[2]: Código da loja do cliente que foi selecionado na venda.

PARAMIXB[3]: Modelo de dados que contém todos os produtos lançados na venda.

Retorno:

Deve-se retornar um lógico .T. ou .F., sendo que:

.T. → prossegue com a abertura da tela de pagamento;

.F. → não prossegue com a abertura da tela de pagamento.


1º - Exemplo de utilização do Ponto de Entrada:

User Function StCallPay()


Local cCodCli       := PARAMIXB[1]  //Codigo do cliente
Local cCodCliLoj    := PARAMIXB[2]  //Codigo da loja do cliente
Local oProdutos     := PARAMIXB[3]  //Produtos registrados na venda
Local nX            := 0            //Variavel de loop

CoNout("O codigo do cliente selecionado na venda eh: " + cCodCli)
CoNout("")
CoNout("")
CoNout("Os itens registrados na venda foram")
CoNout("")
CoNout("")

For nX := 1 To oProdutos:Length()
    oProdutos:GoLine(nX)

    CoNout("Codigo do produto : " + oProdutos:GetValue("L2_PRODUTO"))
    CoNout("Descricao : " + oProdutos:GetValue("L2_DESCRI"))
    CoNout("Quantidade : " + AllTrim(Str(oProdutos:GetValue("L2_QUANT"))))
    CoNout("Preco unitario : " + AllTrim(Str(oProdutos:GetValue("L2_VRUNIT"))))
    CoNout("Valor do produto : " + AllTrim(Str(oProdutos:GetValue("L2_VLRITEM"))))
    CoNout("")
    CoNout("")
Next nX

Return .T.


2º - Exemplo de utilização do Ponto de Entrada:

User Function StCallPay()


If STDGPBasket("SL1","L1_DESCONT") > 0
    CoNout('Ja tem desconto aplicado na venda')
Else
    CoNout('Nao tem desconto aplicado na venda')
EndIf

//Função STWTotDisc responsável em aplicar o desconto no Totvs Pdv
//Parâmetros:
//1º - Indico o valor do desconto
//2º - Indico que o desconto sera em valor 'V', ou poderia passar 'P' para percentual
//3º - Indica a origem que esta sendo chamada a função, não eh um parâmetro obrigatório, pode-se passar em branco
//4º - Indica se o desconto sera cumulativo, ou seja, caso já tenha aplicado um desconto antes de executar esse ponto de entrada,
//o sistema considera o desconto aplicado anteriormente mais o desconto de 10 reais que esta sendo aplicado no ponto de entrada.


STWTotDisc( 10 , 'V' , '' , .F. )

Return .T.



<style>
div.theme-default .ia-splitter #main {
    margin-left: 0px;
}
.ia-fixed-sidebar, .ia-splitter-left {
    display: none;
}
#main {
    padding-left: 10px;
    padding-right: 10px;
    overflow-x: hidden;
}

.aui-header-primary .aui-nav,  .aui-page-panel {
    margin-left: 0px !important;
}
.aui-header-primary .aui-nav {
    margin-left: 0px !important;
}
</style>