XmlGetChild ( < oParent>, < nChild> ) --> oRet

(objeto)
• Retorna o objeto que representa o filho da estrutura, de acordo com o índice passado no parâmetro <nChild>.

• Ao especificar um elemento qualquer do objeto para a função, na qual irá usar como base para retornar o nó filho indicado pelo segundo parâmetro passado para a função.
• Pode-se utilizar essa função para alterar o posicionamento do objeto, para algum nó filho do atual, na estrutura do objeto XML - EXtensible Markup Language (Linguagem extensível de formatação).

/*No exemplo seguinte usamos a função para nos posicionar no nodo &ltitens> e, em seguida apagamos todos os nós filhos
com a xmlDelNode. Usando o comando SAVE criamos um arquivo teste.xml ao final da execução do programa.*/
#INCLUDE "TOTVS.CH"
#INCLUDE "XMLXFUN.CH"
User Function ExeXML1()
Local cError   := ""
Local cWarning := ""
Local oScript
Local cFile := ""

//a partir do rootpath do ambiente
cFile := "\xml\pedido.xml"

//Gera o Objeto XML ref. ao script
oScript := XmlParser( GeraXML(), "_", @cError, @cWarning )
oScript := XmlGetchild( oScript:_PEDIDO , XmlChildCount( oScript:_PEDIDO ))

// Agora vou apagar um node
if !XmlDelNode( oScript , "_ITEM" )
    conout("Nao foi possivel apagar o nodo")
EndIf

//Tranforma o Objeto XML em arquivo
//SAVE oScript XMLFILE "\teste.xml"

Return oScript

Static Function GeraXML()	// Script XML a gerar objeto
Local cScript := '<?xml version="1.0" encoding="UTF-8"?>'
cScript += "<pedido>"
cScript += "  <NomeCliente>Microsiga Software S/A</NomeCliente>"
cScript += "  <Endereco>Av. Braz Leme</Endereco>"
cScript += "  <Numero>1361</Numero>"
cScript += "  <Data>22-03-2005</Data>"
cScript += "  <Itens>"
cScript += "    <Item>"
cScript += "      <Produto>Prothues</Produto>"
cScript += "      <Quantidade>1</Quantidade>"
cScript += "      <Preco>100.00</Preco>"
cScript += "    </Item>"
cScript += "    <Item>"
cScript += "      <Produto>ERP</Produto>"
cScript += "      <Quantidade>0</Quantidade>"
cScript += "      <Preco>0</Preco>"
cScript += "    </Item>"
cScript += "  </Itens>"
cScript += "</pedido>"
Return cScript