01. DADOS GERAIS

Linha de Produto:Microsiga Protheus®
Segmento:Serviços
Módulo:Gestão de Serviços
Função:PNMTABC01.prw
Ticket:7918606
Requisito/Story/Issue (informe o requisito relacionado) :DSERSGS-7562


02. SITUAÇÃO/REQUISITO

Com integração entre Gestão de Serviços e RH, é possível alocar o atendente em outra escala diferente da cadastrado no RH (SRA). Caso o funcionário deixasse de ser um Atendente, não era possível desligar a integração para aquele funcionário.

03. SOLUÇÃO

Implementado no PNMTABC01, no retorno do código do atendente, o campo AA1_MSBLQL. Caso o campo esteja criado e com o valor "1" (Bloqueado), a integração entre GS e GPE para este funcionário será bloqueada.

CampoValores
AA1_MSBLQL

"1" - Bloqueado, ira utilizar do RH

"2" - Desbloqueado, ira utilizar do Gestão de Serviços


Código Antes:

Static Function GetAtend(cFil, cMat)
	Local cCod := ""
	Local cAliasTrb := GetNextAlias()
	
	BeginSQL Alias cAliasTrb
		SELECT AA1_CODTEC
		
		FROM %Table:AA1% AA1
		
		WHERE 
			AA1.AA1_FILIAL = %xFilial:AA1%  AND
			AA1.AA1_CDFUNC = %Exp:cMat% AND
			AA1.AA1_FUNFIL = %Exp:cFil% AND
			AA1.%NotDel%

	EndSQL
	
	If (cAliasTrb)->(!EOF())
		cCod := (cAliasTrb)->AA1_CODTEC
	EndIf
	
	(cAliasTrb)->(DbCloseArea())
	
Return cCod

Alteração: 

Static Function GetAtend(cFil, cMat)
	Local cCod 		:= ""
	Local cAliasTrb := GetNextAlias()
	Local cQuery	:= "%%"
	Local lAA1MSBL	:= AA1->( ColumnPos('AA1_MSBLQL')) > 0
	
	If lAA1MSBL
		cQuery := "%"
		cQuery += " AND AA1.AA1_MSBLQL <> '1' "
		cQuery += "%"
	EndIf
	BeginSQL Alias cAliasTrb
		SELECT AA1_CODTEC
		
		FROM %Table:AA1% AA1
		
		WHERE 
			AA1.AA1_FILIAL = %xFilial:AA1%  AND
			AA1.AA1_CDFUNC = %Exp:cMat% AND
			AA1.AA1_FUNFIL = %Exp:cFil% AND
			AA1.%NotDel%
			%Exp:cQuery%
	EndSQL
	
	If (cAliasTrb)->(!EOF())
		cCod := (cAliasTrb)->AA1_CODTEC
	EndIf
	
	(cAliasTrb)->(DbCloseArea())
	
Return cCod


04. DEMAIS INFORMAÇÕES

Não há.

05. ASSUNTOS RELACIONADOS


<style>
div.theme-default .ia-splitter #main {
    margin-left: 0px;
}
.ia-fixed-sidebar, .ia-splitter-left {
    display: none;
}
#main {
    padding-left: 10px;
    padding-right: 10px;
    overflow-x: hidden;
}

.aui-header-primary .aui-nav,  .aui-page-panel {
    margin-left: 0px !important;
}
.aui-header-primary .aui-nav {
    margin-left: 0px !important;
}

.aui-tabs.horizontal-tabs>.tabs-menu>.menu-item.active-tab a::after { 
	background: #FF9900; !important 
}

.menu-item.active-tab { 
	border-bottom: none !important; 
}

</style>