Exibir origem

Tempo aproximado para leitura: 05 min

01. DADOS GERAIS

Linha de Produto:	Microsiga Protheus®
Segmento:	Jurídico
Módulo:	Pré-faturamento de Serviços - SIGAPFS
Função:	Geração de arquivos E-billing 1998B e 1998BI - TXT - LEDES98

02. PONTO DE ENTRADA

Descrição:

Este ponto de entrada permite a alteração dos campos usados no preenchimento das informações do arquivo e-billing 1998B e 1998B Internacional.

Localização:

Atualizações >> Movimentações >> E-billing LEDES 1998B

Programa Fonte:

LEDES98

Função:

MontaCabec

Ponto de Entrada:

LEDES98Es

Parâmetros:

Nome

Tipo

Descrição

Obrigatório

PARAMIXB

array

Array com 6 posições

Nome	Tipo	Descrição
PARAMIXB[1]	Lógico	Indica se o e-billing é o 1998BI (internacional)
PARAMIXB[2]	Array*	Estrutura dos Dados de Honorários
PARAMIXB[3]	Array*	Estrutura dos Dados de Despesas
PARAMIXB[4]	Array*	Estrutura dos Dados de Lançamentos Tabelados
PARAMIXB[5]	Array*	Estrutura dos Dados de Descontos ou Acréscimos de Faturas
PARAMIXB[6]	Array*	Estrutura dos Dados de Impostos

*Os Arrays de Parâmetros de Entrada/Saída devem possuir a seguinte estrutura:

Nome	Tipo	Descrição
aEstru[01]	Caractere	Cabeçalho do Campo
aEstru[02]	Caractere	Tipo do Dado, onde: F - Fórmula com retorno numérico " " - Expressão com retorno alpha C - Campo
aEstru[03]	Numérico	Tamanho do Campo
aEstru[04]	Numérico	Decimais do Campo
aEstru[05]	Caractere	Nome do Campo** ou Código da Expressão
aEstru[06]	Caractere	Campos específicos**

*Campos utilizados nas querys enviadas aos banco de dados, caso o tipo do campo seja "C" - Será enviada o valor da coluna 5 (Nome do campo); caso contrário, a coluna 6 (Campos específicos).

Para a consulta podem ser utilizados os campos das seguintes tabelas:

Dado	Tabelas Consultadas
Honorários	NXA - Faturas NW0 - Time Sheets Faturamento NUE - Time Sheets NVE - Casos NUR - Complemento do Participante RD0 - Participantes NUH - Complemento do Cliente NRX - Empresas de E-billing CTO - Moedas Contábeis NTQ - Escritório E-Billing NS7 - Escritórios SYA - Países NRV - Categoria E-billing NS0 - Tipo de Atividade de E-billing NRY - Fase E-billing NRZ - Tarefa E-billing
Despesas	NXA - Faturas NVZ - Despesa Faturamento NVY - Despesas NVE - Casos NUR - Complemento do Participante RD0 - Participantes NUH - Complemento do Cliente NRX - Empresas de E-billing CTO - Moedas Contábeis NTQ - Escritório E-Billing NS7 - Escritórios SYA - Países NS2 - Tipo de Categoria E-billing (De/Para) NRV - Categoria E-billing NS4 - Tipo desp E-billing (de-para) NS3 - Tipo de despesa de E-billing
Lançamentos tabelados	NXA - Faturas NW4 - Lancamento Tabelado Fatu NV4 - Lançamentos Tabelados NVE - Casos RD0 - Participantes NUR - Complemento do Participante NUH - Complemento do Cliente NRX - Empresas de E-billing CTO - Moedas Contábeis NTQ - Escritório E-Billing NS7 - Escritórios SYA - Países NRV - Categoria E-billing NXO - Serv Tab E-Billing (de/para) NXN - SERVIÇOS TABELADOS E-BILLING
Acréscimos/Descontos	NXA - Faturas RD0 - Participantes NUH - Complemento do Cliente NRX - Empresas de E-billing CTO - Moedas Contábeis NTQ - Escritório E-Billing NS7 - Escritórios SYA - Países
Impostos	NXA - Faturas RD0 - Participantes NUH - Complemento do Cliente NRX - Empresas de E-billing CTO - Moedas Contábeis NTQ - Escritório E-Billing NS7 - Escritórios SYA - Países

Sim

Retorno:

Nome

Tipo

Descrição

Obrigatório

aRetorno

Array

Array com 6 posições

Nome	Tipo	Descrição
aRetorno[1]	Array*	Estrutura dos Dados de Honorários, se retornado vazio é considerado o padrão.
aRetorno[2]	Array*	Estrutura dos Dados de Despesas, se retornado vazio é considerado o padrão
aRetorno[3]	Array*	Estrutura dos Dados de Lançamentos Tabelados, se retornado vazio é considerado o padrão
aRetorno[4]	Array*	Estrutura dos Dados de Descontos ou Acréscimos de Faturas, se retornado vazio é considerado o padrão
aRetorno[6]	Array*	Estrutura dos Dados de Impostos, se retornado vazio é considerado o padrão

Sim

03. EXEMPLO

User Function Ledes98Es()
Local aCabecHonC := {}
Local aCabecDesC := {}
Local aCabecTabC := {}
Local aCabecAjuC := nil
Local aCabecImpC := nil
Local l1998BI := .F.
Local nC := 0
Local aRet := {}

If ValType(PARAMIXB) == "A" .AND. Len(PARAMIXB) >= 6 .AND. ValType(PARAMIXB[02]) == "A"
    l1998BI := PARAMIXB[01]
    aCabecHonC := aClone(PARAMIXB[02])
    aCabecDesC := aClone(PARAMIXB[03])
    aCabecTabC := aClone(PARAMIXB[04])

    For nC := 1 to Len(aCabecHonC)
        Do Case
        Case aCabecHonC[nC, 05] = "RD0_NOME"
            aCabecHonC[nC, 05] := "NUR_APELI"
        Case aCabecHonC[nC, 05] == "EXP21"
            aCabecHonC[nC, 06] := "NUR_APELI"
        Case aCabecHonC[nC, 05] == "EXP22"
            aCabecHonC[nC, 06] := "NUR_APELI"
        EndCase

    Next nC

    aAdd(aRet, aClone(aCabecHonC))

    For nC := 1 to Len(aCabecDesC)
        Do Case
        Case aCabecDesC[nC, 05] = "RD0_NOME"
            aCabecDesC[nC, 05] := "NUR_APELI"
        Case aCabecDesC[nC, 05] == "EXP21"
            aCabecDesC[nC, 06] := "NUR_APELI"
        Case aCabecDesC[nC, 05] == "EXP22"
            aCabecDesC[nC, 06] := "NUR_APELI"
        EndCase

    Next nC
    aAdd(aRet, aClone(aCabecDesC))

    For nC := 1 to Len(aCabecTabC)
        Do Case
        Case aCabecTabC[nC, 05] = "RD0_NOME"
            aCabecTabC[nC, 05] := "NUR_APELI"
        Case aCabecTabC[nC, 05] == "EXP21"
            aCabecTabC[nC, 06] := "NUR_APELI"
        Case aCabecTabC[nC, 05] == "EXP22"
            aCabecTabC[nC, 06] := "NUR_APELI"
        EndCase

    Next nC
    aAdd(aRet, aClone(aCabecTabC))

    aAdd(aRet, aClone(aCabecAjuC) )

    aAdd(aRet, aClone(aCabecImpC))

Else
    aRet := Array(5)
EndIf
Return aRet

//-------------------------------------------------------------------
/*/{Protheus.doc} LedesPart
Expressão que trata o retorno do Nome ou Sobrenome do participante, conforme o tipo do Arquivo
@param nOpc - Opção de Retorno
@param cNomePart - Retorno do tipo de Nome do Participante
@version 1.0
/*/
//-------------------------------------------------------------------
User Function LedesPart(nOpc)
Local cNomePart := ""
Default nOpc    := 1

Do Case
Case nOpc == 1
    cNomePart := Alltrim(Posicione('NUR',1,xFilial('NUR')+FIELD->NUE_CPART2,'NUR_APELI'))
    cNomePart := Substr(cNomePart,Rat(" ", cNomePart)+1,Len(cNomePart))
Case nOpc == 2
    cNomePart := Alltrim(Posicione('NUR',1,xFilial('NUR')+FIELD->NUE_CPART2,'NUR_APELI'))
    cNomePart := Substr(cNomePart,1,At(" ", cNomePart)-1)
Case nOpc == 3
    cNomePart := Alltrim(Posicione('NUR',1,xFilial('NUR')+FIELD->NVY_CPART,'NUR_APELI'))
    cNomePart := Substr(cNomePart,Rat(" ", cNomePart)+1,Len(cNomePart))
Case nOpc == 4
    cNomePart := Alltrim(Posicione('NUR',1,xFilial('NUR')+FIELD->NVY_CPART,'NUR_APELI'))
    cNomePart := Substr(cNomePart,Rat(" ", cNomePart)+1,Len(cNomePart))
Case nOpc == 5
    cNomePart := Alltrim(Posicione('NUR',1,xFilial('NUR')+FIELD->NV4_CPART,'NUR_APELI'))
    cNomePart := Substr(cNomePart,Rat(" ", cNomePart)+1,Len(cNomePart))
Case nOpc == 6
    cNomePart := Alltrim(Posicione('NUR',1,xFilial('NUR')+FIELD->NV4_CPART,'NUR_APELI'))
    cNomePart := Substr(cNomePart,Rat(" ", cNomePart)+1,Len(cNomePart))

EndCase

Return cNomePart

<style>
div.theme-default .ia-splitter #main {
    margin-left: 0px;
}
.ia-fixed-sidebar, .ia-splitter-left {
    display: none;
}
#main {
    padding-left: 10px;
    padding-right: 10px;
    overflow-x: hidden;
}

.aui-header-primary .aui-nav,  .aui-page-panel {
    margin-left: 0px !important;
}
.aui-header-primary .aui-nav {
    margin-left: 0px !important;
}
</style>