Ponto de Entrada executado na abertura da rotina QADA130

Descrição:

QAD130TO - Ponto de Entrada executado após na abertura da rotina QADA130 para alteração das informações mostradas no campo Tópico.

Versões:

Microsiga Protheus 12

Idioma:

Português (Brasil)

Sistemas Operacionais Suportados:

Todos

Compatível com as Bases de Dados:

Todos

Parâmetros:

PARAMIXB[1] - Array com os números dos check list da Auditoria

PARAMIXB[2] - Objeto da sequência da área auditada selecionada

PARAMIXB[3] - Objeto do número do check list selecionado

PARAMIXB[4] - Objeto do tópico do check list selecionado

PARAMIXB[5] - Array com as sequências das áreas da auditoria

Retorno:

aRet[1] - Array com as chaves do check list

aRet[2] - As informações que irão aparecer no combo do Tópico

Eventos de chamada de Ponto de Entrada:Na abertura da rotina QADA130
Programa Fonte:QADA130.PRW
#include "protheus.ch"

User Function QAD130TO()

    Local aCheckList    := PARAMIXB[1]
    Local oCombo1       := PARAMIXB[2]
    Local oCombo2       := PARAMIXB[3]
    Local oCombo3       := PARAMIXB[4]
    Local aSeq          := PARAMIXB[5]
    Local aRet          := {}

    QU2->(dbSeek(xFilial("QU2") + aCheckList[1, oCombo2:nAt]))
	Aadd(aRet, {})
	Aadd(aRet, {})
	dbSelectArea("QUD")
	dbSetOrder(1)
	dbSeek(xFilial("QUD") + QUB->QUB_NUMAUD + aSeq[1, oCombo1:nAt] + aCheckList[1, oCombo2:nAt])
	While !Eof() .and. QUD->QUD_FILIAL + QUD->QUD_NUMAUD + QUD->QUD_SEQ + QUD->QUD_CHKLST + QUD->QUD_REVIS == xFilial("QUD") + QUB->QUB_NUMAUD + aSeq[1, oCombo1:nAt] + aCheckList[1, oCombo2:nAt]
		If aScan(aRet[1], QUD->QUD_CHKLST+QUD->QUD_REVIS+QUD->QUD_CHKITE) == 0
			dbSelectArea("QU3")
			dbSetOrder(1)
			dbSeek(xFilial("QU3") + QUD->QUD_CHKLST+QUD->QUD_REVIS+QUD->QUD_CHKITE)
			Aadd(aRet[1], QUD->QUD_CHKLST+QUD->QUD_REVIS+QUD->QUD_CHKITE)
			Aadd(aRet[2], AllTrim(QU3->QU3_CHKITE) + " - " + AllTrim(QU3->QU3_NORMA) + " " + QU3->QU3_DESCRI)
			dbSelectArea("QUD")
		Endif
		dbSkip()
	Enddo

Return aRet