Para visualizar um novo card ou gráfico disponibilizado na API de exemplo é necessário criar um novo tipo de card/gráfico. Segue abaixo o exemplo da carga a ser realizada nas tabelas A1N e A1P para criação dos novos tipos de card e gráfico.
#INCLUDE "TOTVS.CH"
#INCLUDE "RESTFUL.CH"
//------------------------------------------------------------------------
/*/{Protheus.doc} cargaExemplo
Exemplo de carga a ser feita no Card e Gráfico para funcionamento da API de Exemplo
@author Squad CRM & Faturamento
@since 16/12/2021
@version 12.1.33
/*/
//------------------------------------------------------------------------
Function cargaExemplo()
Local aAreaA1N := A1N->(GetArea())
Local aAreaA1P := A1P->(GetArea())
Local nX := 0
Local nY := 0
If !A1N->(DbSeek(xFilial("A1N")))
aA1N := CargaA1NAB()
AAdd(aTables,aA1N)
EndIf
If !A1P->(DbSeek(xFilial("A1P")))
aA1P := CargaA1PAB()
AAdd(aTables,aA1P)
EndIf
For nX := 1 to Len(aA1N)
RecLock("A1N", .T.)
For nY := 1 To Len(aA1N[nX])
FieldPut(FieldPos(aA1N[nX][nY][1]), aA1N[nX][nY][2])
Next
A1N->(MsUnlock())
Next
For nX := 1 to Len(aA1P)
RecLock("A1P", .T.)
For nY := 1 To Len(aA1P[nX])
FieldPut(FieldPos(aA1P[nX][nY][1]) , aA1P[nX][nY][2])
Next
A1P->(MsUnlock())
Next
RestArea(aAreaA1N)
RestArea(aAreaA1P)
Return
Static Function CargaA1NAB()
Local aRet := {}
aAdd(aRet,{;
{"A1N_FILIAL ", xFilial("A1N")},;
{"A1N_ID ", "000012"},;
{"A1N_CARSER ", "/exemplo1/cards/cardInfo"},;
{"A1N_FLDSER ", "/exemplo1/cards/fieldsInfo"},;
{"A1N_ITSER ", "/exemplo1/cards/itemsDetails"},;
{"A1N_CABSER ", "/exemplo1/cards/headerItens"},;
{"A1N_TITULO ", "Exemplo API"};
})
Return aRet
Static Function CargaA1PAB()
Local aRet := {}
aAdd(aRet, {;
{"A1P_FILIAL", xFilial("A1P")},;
{"A1P_ID ", "000008"},;
{"A1P_SRVFOR", "/exemplo2/charts/form"},;
{"A1P_SRVDAT", "/exemplo2/charts/retDados"},;
{"A1P_TITULO", "Exemplo API"},;
{"A1P_MAXNIV", 2},;
{"A1P_ITSERV", "/exemplo2/charts/itemsDetails"};
})
Return aRet |
|
Disponibiliza uma API REST no Dashboard para visualizar um Card.
#INCLUDE "TOTVS.CH"
#INCLUDE "RESTFUL.CH"
//-------------------------------------------------------------------
/*/{Protheus.doc} Exemplo1
Exemplo de API de integração de Cards
@author Squad CRM & Faturamento
@since 26/03/2020
@version 12.1.27
/*/
//-------------------------------------------------------------------
WSRESTFUL Exemplo1 DESCRIPTION "Exemplo 1"
WSDATA Fields AS STRING OPTIONAL
WSDATA Order AS STRING OPTIONAL
WSDATA Page AS INTEGER OPTIONAL
WSDATA PageSize AS INTEGER OPTIONAL
WSMETHOD POST itemsDetails ;
DESCRIPTION "Carrega os Itens Utilizados para Montagem do Painel" ;
WSSYNTAX "/cards/itemsDetails/{Order, Page, PageSize, Fields}" ;
PATH "/cards/itemsDetails";
PRODUCES APPLICATION_JSON
WSMETHOD GET cardFilter;
DESCRIPTION "Disponibiliza os campos que poderão ser utilizados no filtro do Card" ;
WSSYNTAX "/cards/cardFilter/" ;
PATH "/cards/cardFilter";
PRODUCES APPLICATION_JSON
WSMETHOD GET cardInfo ;
DESCRIPTION "Carrega as informações do Painel" ;
WSSYNTAX "/cards/cardInfo/" ;
PATH "/cards/cardInfo";
PRODUCES APPLICATION_JSON
WSMETHOD GET fieldsInfo ;
DESCRIPTION "Carrega os campos que podem que ser utilizados" ;
WSSYNTAX "/cards/fieldsInfo/" ;
PATH "/cards/fieldsInfo";
PRODUCES APPLICATION_JSON
ENDWSRESTFUL
//-------------------------------------------------------------------
/*/{Protheus.doc} POST itemsDetails
Carrega os Itens Utilizados para Montagem do Painel
@author Squad CRM & Faturamento
@since 28/07/2020
@version 12.1.27
/*/
//-------------------------------------------------------------------
WSMETHOD POST itemsDetails WSRECEIVE Order, Page, PageSize, Fields WSSERVICE Exemplo1
Local aHeader := {}
Local aRet := {}
Local cError := "Erro na Requisição"
Local lRet := .T.
Local oCoreDash := CoreDash():New()
Self:SetContentType("application/json")
aHeader := {;
{"num" , "Numero" },;
{"prefixo" , "Prefixo" },;
{"parcela" , "Loja" },;
{"tipo" , "Tipo" },;
{"naturez" , "Natureza" };
}
//Chama a função responsavel por montar a Expressão SQL
aRet := MntQuery()
//Define a Query padrão utilizada no Serviço
oCoreDash:SetQuery(aRet[1])
oCoreDash:SetWhere(aRet[2])
oCoreDash:SetFields(DePara())
oCoreDash:SetApiQstring(Self:aQueryString)
lRet := oCoreDash:BuildJson()
If lRet
oCoreDash:SetPOHeader(aHeader)
Self:SetResponse( oCoreDash:ToObjectJson())
Else
cError := oCoreDash:GetJsonError()
SetRestFault( 500, EncodeUtf8(cError) )
EndIf
oCoreDash:Destroy()
aSize(aRet, 0)
aSize(aHeader, 0)
Return lRet
//-------------------------------------------------------------------
/*/{Protheus.doc} GET cardFilter
Retorna os campos que poderão ser filtrados
@author Squad CRM & Faturamento
@since 28/07/2020
@version 12.1.27
/*/
//-------------------------------------------------------------------
WSMETHOD GET cardFilter WSSERVICE Exemplo1
Local aHeader := {}
Local oCoreDash := CoreDash():New()
Local oResponse := JsonObject():New()
aHeader := {;
{"num" , "Numero" },;
{"prefixo" , "Prefixo" },;
{"parcela" , "Loja" },;
{"tipo" , "Tipo" },;
{"naturez" , "Natureza" };
}
oResponse["items"] := oCoreDash:SetPOHeader(aHeader)
Self:SetResponse( EncodeUtf8(oResponse:ToJson()))
Return .T.
//-------------------------------------------------------------------
/*/{Protheus.doc} GET cardInfo
Método para retornar os dados do Card
@author Squad CRM & Faturamento
@since 28/07/2020
@version 12.1.27
/*/
//-------------------------------------------------------------------
WSMETHOD GET cardInfo WSRESTFUL Exemplo1
Local aFilter := {}
Local cWhere := ""
Local nFiltro := 0
Local oCoreDash := CoreDash():New()
Local oResponse := JsonObject():New()
//Converte os campos utilizados na consulta para os campos utilizados no card.
oCoreDash:SetFields(DePara())
//Converte o Filtro informado no parametro Query String.
oCoreDash:SetApiQstring(Self:aQueryString)
aFilter := oCoreDash:GetApiFilter()
For nFiltro := 1 to Len(aFilter)
cWhere += " AND " + aFilter[nFiltro][1]
Next
RetCardInfo( @oResponse )
self:SetResponse( EncodeUtf8(FwJsonSerialize(oResponse,.T.,.T.)) )
oResponse := Nil
FreeObj( oResponse )
oCoreDash:Destroy()
FreeObj( oCoreDash )
Return .T.
//-------------------------------------------------------------------
/*/{Protheus.doc} GET fieldsInfo
Carrega os campos que podem que ser utilizados
@param cSelect, Caractere, Campos que serão retornados no SELECT
@author Squad CRM & Faturamento
@since 28/07/2020
@version 12.1.27
/*/
//-------------------------------------------------------------------
WSMETHOD GET fieldsInfo WSSERVICE Exemplo1
Local aItems := {}
Local oResponse := JsonObject():New()
Local oCoreDash := CoreDash():New()
aAdd(aItems, { "total" , "Total a Receber:" })
aAdd(aItems, { "antigo" , "Titulo mais Antigo:" })
aAdd(aItems, { "saldo" , "Saldo Total:" })
/*Retorna um Objeto no formato de Value e Label*/
oResponse["items"] := oCoreDash:SetPOCombo(aItems)
Self:SetResponse( EncodeUtf8(oResponse:ToJson()))
Return .T.
//-------------------------------------------------------------------
/*/{Protheus.doc} MntQuery
Monta a query responsável por trazer os itens utilizados no Painel
@param cSelect, Caractere, Campos que serão retornados no SELECT
@author Squad CRM & Faturamento
@since 28/07/2020
@version 12.1.27
/*/
//-------------------------------------------------------------------
Static Function MntQuery(cCampos)
Local cQuery
Local cWhere
Default cCampos := " SE1.E1_PREFIXO, SE1.E1_NUM, SE1.E1_PARCELA, SE1.E1_TIPO, SE1.E1_NATUREZ "
cQuery := " SELECT " + cCampos + " FROM " + RetSqlName("SE1") + " SE1 "
cWhere := " SE1.E1_FILIAL = '" + xFilial("SE1") + "' "
cWhere += " AND SE1.D_E_L_E_T_ = ' ' "
Return {cQuery, cWhere}
//-------------------------------------------------------------------
/*/{Protheus.doc} DePara
Efetua o Conversão entre os atributos objetos do Json e os campos utilizados na Consulta
@author Squad CRM & Faturamento
@since 28/07/2020
@version 12.1.27
/*/
//-------------------------------------------------------------------
Static Function DePara()
Local aCampos := {}
aCampos := {;
{"prefixo" , "SE1.E1_PREFIXO" },;
{"num" , "SE1.E1_NUM" },;
{"parcela" , "SE1.E1_PARCELA" },;
{"tipo" , "SE1.E1_TIPO" },;
{"naturez" , "SE1.E1_NATUREZ" };
}
Return aCampos
//-------------------------------------------------------------------
/*/{Protheus.doc} GET RetCardInfo
Retorna os dados que poderão ser apresentados no painel
@author Squad CRM & Faturamento
@since 28/07/2020
@version 12.1.27
/*/
//-------------------------------------------------------------------
Static Function RetCardInfo( oResponse )
Local oItem
Local aItems := {}
oItem := JsonObject():New()
oItem["total"] := 'R$ 526.232.123,23'
oItem["antigo"] := '02/04/2020'
oItem["salto"] := 'R$ 265.235.201,33'
aAdd(aItems, oItem)
oResponse['hasNext'] := 'false'
oResponse["items"] := aItems
Return Nil |
|
Disponibiliza uma API REST no Dashboard para visualizar um gráfico de Pizza ou Polar.
#INCLUDE "TOTVS.CH"
#INCLUDE "RESTFUL.CH"
//------------------------------------------------------------------------
/*/{Protheus.doc} Exemplo2
Exemplo de API de integração de Graficos de Pizza e/ou Polar
@author Squad CRM & Faturamento
@since 26/03/2020
@version 12.1.27
/*/
//------------------------------------------------------------------------
WSRESTFUL Exemplo2 DESCRIPTION "Exemplo de API - Grafico Pizza e Polar"
WSDATA JsonFilter AS STRING OPTIONAL
WSDATA drillDownFilter AS STRING OPTIONAL
WSDATA Page AS INTEGER OPTIONAL
WSDATA PageSize AS INTEGER OPTIONAL
WSMETHOD GET form ;
DESCRIPTION "Form de Cadastro do Gráfico" ;
WSSYNTAX "/charts/form/" ;
PATH "/charts/form";
PRODUCES APPLICATION_JSON
WSMETHOD GET filterItens ;
DESCRIPTION "Carrega os filtros adicionais disponíveis para o gráfico" ;
WSSYNTAX "/charts/filterItens/" ;
PATH "/charts/filterItens";
PRODUCES APPLICATION_JSON
WSMETHOD POST retdados ;
DESCRIPTION "Retorna as Informações do Gráfico" ;
WSSYNTAX "/charts/retdados/{JsonFilter}" ;
PATH "/charts/retdados";
PRODUCES APPLICATION_JSON
WSMETHOD POST itemsDetails ;
DESCRIPTION "Carrega o detalhamento do gráfico" ;
WSSYNTAX "/charts/itemsDetails/{JsonFilter}" ;
PATH "/charts/itemsDetails";
PRODUCES APPLICATION_JSON
ENDWSRESTFUL
//-------------------------------------------------------------------
/*/{Protheus.doc} GET form
Retorna os campos que apresentados no Cadastro do Grafico.
Devera seguir o formato do Dynamic Form do PO-UI.
https://po-ui.io/tools/dynamic-form
@author Squad CRM & Faturamento
@since 28/07/2020
@version 12.1.27
/*/
//-------------------------------------------------------------------
WSMETHOD GET form WSSERVICE Exemplo2
Local oResponse := JsonObject():New()
Local oCoreDash := CoreDash():New()
oCoreDash:SetPOForm("Tipo de Gráfico" , "charttype" , 6 , "Tipo de Gráfico" , .T., "string",;
oCoreDash:SetPOCombo({{"pie","Pizza"},{"polarArea","Polar"}}))
oCoreDash:SetPOForm("Datas" , "datainicio" , 6 , "Dt. Emissão De" , .T., "date")
oCoreDash:SetPOForm("" , "datafim" , 6 , "Dt. Emissão Ate" , .T., "date")
oResponse := oCoreDash:GetPOForm()
Self:SetResponse( EncodeUtf8(oResponse:ToJson()))
Return .T.
//-------------------------------------------------------------------
/*/{Protheus.doc} GET filterItens
Retorna os campos que poderão ser filtrados
@author Squad CRM & Faturamento
@since 28/07/2020
@version 12.1.27
/*/
//-------------------------------------------------------------------
WSMETHOD GET filterItens WSSERVICE Exemplo2
Local aItems := {}
Local oResponse := JsonObject():New()
Local oCoreDash := CoreDash():New()
aAdd(aItems, { "customerId" , "Cod. Cliente" })
aAdd(aItems, { "store" , "Loja" })
aAdd(aItems, { "state" , "Estado" })
/*Retorna um Objeto no formato de property e Label*/
oResponse["items"] := oCoreDash:SetPOHeader(aItems)
Self:SetResponse( EncodeUtf8(oResponse:ToJson()))
Return .T.
//-------------------------------------------------------------------
/*/{Protheus.doc} POST retdados
Retorna um objeto JSON com as informações e valores do Grafico
@author Squad CRM & Faturamento
@since 28/07/2020
@version 12.1.27
/*/
//-------------------------------------------------------------------
WSMETHOD POST retdados WSRECEIVE JsonFilter WSSERVICE Exemplo2
Local oResponse := JsonObject():New()
Local oCoreDash := CoreDash():New()
Local oJson := JsonObject():New()
oJson:FromJson(DecodeUtf8(Self:GetContent()))
retDados(@oResponse, oCoreDash, oJson)
Self:SetResponse( EncodeUtf8(oResponse:ToJson()))
oResponse := Nil
FreeObj( oResponse )
oCoreDash:Destroy()
FreeObj( oCoreDash )
Return .T.
//-------------------------------------------------------------------
/*/{Protheus.doc} POST retdados
Retorna os items utilizado no Drilldown
@author Squad CRM & Faturamento
@since 28/07/2020
@version 12.1.27
/*/
//-------------------------------------------------------------------
WSMETHOD POST itemsDetails WSRECEIVE JsonFilter, drillDownFilter WSRESTFUL Exemplo2
Local aHeader := {}
Local aItems := {}
Local aRet := {}
Local cBody := DecodeUtf8(Self:GetContent())
Local cError := "Erro na Requisição"
Local cSelect := ""
Local cWhere := ""
Local lRet := .T.
Local oCoreDash := CoreDash():New()
Local oBody := JsonObject():New()
Local oJsonFilter := JsonObject():New()
Local oJsonDD := JsonObject():New()
If !Empty(cBody)
oBody:FromJson(cBody)
If ValType(oBody["chartFilter"]) == "J"
oJsonFilter := oBody["chartFilter"]
EndIf
If ValType(oBody["detailFilter"]) == "A"
oJsonDD := oBody["detailFilter"]
EndIf
EndIf
Self:SetContentType("application/json")
If oJsonFilter:GetJsonText("level") == "null" .Or. Len(oJsonFilter["level"]) == 0
If Len(oJsonDD) == 0 //Nivel 1 do Drilldown
aHeader := {;
{"document" , "Documento" ,"link" },;
{"series" , "Serie" },;
{"state" , "UF" },;
{"documentType" , "Tipo" },;
{"dateOfIssue" , "Emissão" };
}
aItems := {;
{"document" , "F2_DOC" },;
{"series" , "F2_SERIE" },;
{"state" , "F2_EST" },;
{"documentType" , "F2_TIPO" },;
{"dateOfIssue" , "F2_EMISSAO" };
}
cSelect := " F2_DOC, F2_SERIE, F2_EST, F2_TIPO, F2_EMISSAO, F2_TIPO "
aRet := QuerySF2(cSelect)
Elseif Len(oJsonDD) == 1 //Nivel 2 do Drilldown
aHeader := {;
{"D2_ITEM" , "Item" },;
{"D2_COD" , "Cod. Produto", "link" },;
{"B1_DESC" , "Desc. Produto " },;
{"D2_PRCVEN", "Vlr.Unitario", "currency","BRL" },;
{"D2_QUANT" , "Quantidade","number",'1.2-5' },;
{"D2_TOTAL" , "Vlr. Total", "currency","BRL" },;
{"D2_LOCAL" , "Armazem" };
}
aItems := {;
{"D2_ITEM" , "D2_ITEM"},;
{"D2_COD" , "D2_COD"},;
{"B1_DESC" , "B1_DESC"},;
{"D2_PRCVEN" , "D2_PRCVEN"},;
{"D2_QUANT" , "D2_QUANT"},;
{"D2_TOTAL" , "D2_TOTAL"},;
{"D2_LOCAL" , "D2_LOCAL"};
}
cSelect := " D2_ITEM, D2_COD, B1_DESC, D2_PRCVEN, D2_QUANT, D2_TOTAL, D2_LOCAL "
cWhere := " D2_DOC = '" + oJsonDD[1]['document'] + "' AND D2_SERIE = '" + oJsonDD[1]['series'] + "' "
aRet := QuerySD2(cSelect, cWhere)
Endif
Else
//Monta o Drilldown do grafico nivel 2
aHeader := {;
{"document" , "Documento" },;
{"series" , "Serie" },;
{"state" , "UF" },;
{"documentType" , "Tipo" },;
{"dateOfIssue" , "Emissão" };
}
aItems := {;
{"document" , "F2_DOC" },;
{"series" , "F2_SERIE" },;
{"state" , "F2_EST" },;
{"documentType" , "F2_TIPO" },;
{"dateOfIssue" , "F2_EMISSAO" };
}
cSelect := " F2_DOC, F2_SERIE, F2_EST, F2_TIPO, F2_EMISSAO, F2_TIPO "
aRet := QuerySF2(cSelect)
EndIf
oCoreDash:SetQuery(aRet[1])
oCoreDash:SetWhere(aRet[2])
oCoreDash:SetFields(aItems)
oCoreDash:SetApiQstring(Self:aQueryString)
oCoreDash:BuildJson()
If lRet
oCoreDash:SetPOHeader(aHeader)
Self:SetResponse( oCoreDash:ToObjectJson() )
Else
cError := oCoreDash:GetJsonError()
SetRestFault( 500, EncodeUtf8(cError) )
EndIf
oCoreDash:Destroy()
FreeObj(oJsonDD)
FreeObj(oJsonFilter)
FreeObj(oBody)
aSize(aRet, 0)
aSize(aItems, 0)
aSize(aHeader, 0)
Return lRet
//-------------------------------------------------------------------
/*/{Protheus.doc} retDados
Retorna os dados que poderão ser apresentados no Grafico
@author Squad CRM & Faturamento
@since 28/07/2020
@version 12.1.27
/*/
//-------------------------------------------------------------------
Static Function retDados(oResponse, oCoreDash, oJson)
Local aData := {}
Local aDataFim := {}
Local aCab := {}
Local aCores := oCoreDash:GetColorChart()
Local nLoop := 0
If oJson:GetJsonText("level") == "null" .Or. Len(oJson["level"]) == 0
aCab := GetUF()
For nLoop := 1 To Len(aCab)
aAdd(aData, Randomize(1,999) )
Next nLoop
aDataFim := {}
aAdd(aDataFim, oCoreDash:SetChart(aCab,aData,/*lCurrency*/,,"Nota fiscal por Estado"))
ElseIf Len(oJson["level"]) == 1
aCab := GetTipoNF()
For nLoop := 1 To Len(aCab)
aAdd(aData, Randomize(1,999) )
Next nLoop
aAdd(aDataFim, oCoreDash:SetChart(aCab,aData,/*lCurrency*/,"pie","Quantidade de Notas por Tipos"))
ElseIf Len(oJson["level"]) == 2
aCab := GetTopCli()
For nLoop := 1 To Len(aCab)
aAdd(aData, Randomize(1, 999) )
Next nLoop
oCoreDash:SetChartInfo( aData, 'Notas', 'bar', aCores[8][3] ) //Cor utilizada: OrangeLht
aAdd(aDataFim, oCoreDash:SetChart(aCab,,/*lCurrency*/,"bar","TOP 10 Clientes por Tipo de Nota"))
Endif
oResponse["items"] := aDataFim
Return Nil
//-------------------------------------------------------------------
/*/{Protheus.doc} QuerySF2
Monta a query responsável por trazer os registro da Nota fiscal
@param cSelect, Caractere, Campos que serão retornados no SELECT
@param cFilter, Caractere, Filtro complementar utilizado na clausula WHERE
@author Squad CRM & Faturamento
@since 28/07/2020
@version 12.1.27
/*/
//-------------------------------------------------------------------
Static Function QuerySF2(cSelect, cFilter )
Local cQuery
Local cWhere
Default cSelect := " SF2.F2_DOC, SF2.F2_SERIE, SF2.F2_CLIENTE, SF2.F2_LOJA, SF2.F2_TIPO "
Default cFilter := ""
cQuery := " SELECT " + cSelect + " FROM " + RetSqlName("SF2") + " SF2 "
cWhere := " SF2.F2_FILIAL = '" + xFilial("SF2") + "' "
If !Empty(cFilter)
cWhere += " AND " + cFilter
Endif
cWhere += " AND SF2.D_E_L_E_T_ = ' ' "
Return { cQuery, cWhere }
//-------------------------------------------------------------------
/*/{Protheus.doc} QuerySD2
Monta a query responsável por trazer os registro da Nota fiscal
@param cSelect, Caractere, Campos que serão retornados no SELECT
@param cFilter, Caractere, Filtro complementar utilizado na clausula WHERE
@author Squad CRM & Faturamento
@since 28/07/2020
@version 12.1.27
/*/
//-------------------------------------------------------------------
Static Function QuerySD2(cSelect, cFilter)
Local cQuery
Local cWhere
Default cSelect := " SD2.D2_DOC, SD2.D2_ITEM, SD2.D2_COD "
Default cFilter := ""
cQuery := " SELECT " + cSelect + " FROM " + RetSqlName("SD2") + " SD2 "
cQuery += " INNER JOIN SB1T10 SB1 "
cQuery += " ON B1_COD = D2_COD AND SB1.D_E_L_E_T_ = ' ' AND B1_FILIAL = '" + xFilial("SB1") + "' "
cWhere := " SD2.D2_FILIAL = '" + xFilial("SD2") + "' "
If !Empty(cFilter)
cWhere += " AND " + cFilter
Endif
cWhere += " AND SD2.D_E_L_E_T_ = ' ' "
Return {cQuery, cWhere}
//-------------------------------------------------------------------
/*/{Protheus.doc} GetUF
Retorna UF
@author Aline Navarro
@since 22/12/2020
@version 12.1.27
/*/
//-------------------------------------------------------------------
Static Function GetUF()
Local aUF := {}
Local aUFX5 := {}
Local nX := 0
Local nLenAUFX5 := 0
aUFX5 := FWGetSX5("12")
nLenAUFX5 := Len(aUFX5)
For nX := 1 To nLenAUFX5
aAdd(aUF,RTrim(aUFX5[nX,3])) //X5_CHAVE
Next nX
Return aUF
|
|
Disponibiliza uma API REST no Dashboard para visualizar um gráfico de Pizza ou Polar.
#INCLUDE "TOTVS.CH"
#INCLUDE "RESTFUL.CH"
//------------------------------------------------------------------------
/*/{Protheus.doc} Exemplo3
Exemplo de API de integração de Graficos de Barra e Linha
@author Squad CRM & Faturamento
@since 28/07/2020
@version 12.1.27
/*/
//------------------------------------------------------------------------
WSRESTFUL Exemplo3 DESCRIPTION "Exemplo de API - Grafico Barra e Linha"
WSDATA JsonFilter AS STRING OPTIONAL
WSDATA drillDownFilter AS STRING OPTIONAL
WSDATA Fields AS STRING OPTIONAL
WSDATA Order AS STRING OPTIONAL
WSDATA Page AS INTEGER OPTIONAL
WSDATA PageSize AS INTEGER OPTIONAL
WSMETHOD GET form ;
DESCRIPTION "Formulario de Cadastro do Gráfico" ;
WSSYNTAX "/charts/form/" ;
PATH "/charts/form";
PRODUCES APPLICATION_JSON
WSMETHOD GET filterItens ;
DESCRIPTION "Retorna todos os filtros adicionar do gráfico." ;
WSSYNTAX "/charts/filterItens/" ;
PATH "/charts/filterItens";
PRODUCES APPLICATION_JSON
WSMETHOD POST retDados ;
DESCRIPTION "Deverá retornar as informações apresentadas no gráfico." ;
WSSYNTAX "/charts/retDados/{JsonFilter}" ;
PATH "/charts/retDados";
PRODUCES APPLICATION_JSON
WSMETHOD POST itemsDetails ;
DESCRIPTION "Carrega o detalhamento do gráfico" ;
WSSYNTAX "/charts/itemsDetails/{JsonFilter}" ;
PATH "/charts/itemsDetails";
PRODUCES APPLICATION_JSON
ENDWSRESTFUL
//-------------------------------------------------------------------
/*/{Protheus.doc} GET form
Retorna os campos que serão apresentados no formulário.
O padrão do campo deve seguir o Dynamic Form do Portinari.
@author Squad CRM & Faturamento
@since 27/03/2020
@version Protheus 12.1.27
/*/
//-------------------------------------------------------------------
WSMETHOD GET form WSSERVICE Exemplo3
Local oResponse := JsonObject():New()
Local oCoreDash := CoreDash():New()
oCoreDash:SetPOForm("Tipo de Gráfico", "charttype" , 6, "Tipo de Gráfico" , .T., "string" , oCoreDash:SetPOCombo({{"line","Linha"}, {"bar","Barra"}}))
oCoreDash:SetPOForm("Filtros" , "dateIni" , 6, "Data Inicial" , .T., 'date' , , .T.)
oCoreDash:SetPOForm("" , "dateFim" , 6, "Data Final" , .T., 'date' , , .T.)
oResponse := oCoreDash:GetPOForm()
Self:SetResponse( EncodeUtf8(oResponse:ToJson()))
Return .T.
//-------------------------------------------------------------------
/*/{Protheus.doc} GET filterItens
Retorna os campos que poderão ser filtrados no Gráfico
@author Squad CRM & Faturamento
@since 27/03/2020
@version Protheus 12.1.27
/*/
//-------------------------------------------------------------------
WSMETHOD GET filterItens WSSERVICE Exemplo3
Local aItems := {}
Local oItem
Local oResponse := JsonObject():New()
oItem := JsonObject():New()
oItem["property"] := "product"
oItem["label"] := "Produto"
aAdd(aItems, oItem)
oItem := JsonObject():New()
oItem["property"] := "salesman"
oItem["label"] := "Vendedor"
aAdd(aItems, oItem)
oItem := JsonObject():New()
oItem["property"] := "cod"
oItem["label"] := "Código"
aAdd(aItems, oItem)
oResponse["items"] := aItems
Self:SetResponse( EncodeUtf8(oResponse:ToJson()))
Return .T.
//-------------------------------------------------------------------
/*/{Protheus.doc} POST retDados
Retorna os dados do Gráfico
@author Squad CRM & Faturamento
@since 27/03/2020
@version Protheus 12.1.27
/*/
//-------------------------------------------------------------------
WSMETHOD POST retDados WSRECEIVE JsonFilter WSSERVICE Exemplo3
Local oResponse := JsonObject():New()
Local oCoreDash := CoreDash():New()
Local oJson := JsonObject():New()
oJson:FromJson(DecodeUtf8(Self:GetContent()))
retDados(@oResponse, oCoreDash, oJson)
Self:SetResponse( EncodeUtf8(oResponse:ToJson()))
oResponse := Nil
FreeObj( oResponse )
oCoreDash:Destroy()
FreeObj( oCoreDash )
Return .T.
//-------------------------------------------------------------------
/*/{Protheus.doc} GET retDados
Retorna o valor das Meta e o Valor Vendido de acordo com parâmetros
informados
@author Squad CRM & Faturamento
@since 27/03/2020
@version Protheus 12.1.27
/*/
//-------------------------------------------------------------------
Static Function retDados(oResponse, oCoreDash, oJson)
Local aData := {}
Local aDataFim := {}
Local aData1 := {}
Local aData2 := {}
Local aData3 := {}
Local aData4 := {}
Local aData5 := {}
Local aCab := {}
Local aCores := oCoreDash:GetColorChart()
Local aSaldo := {}
Local nSaldo := 0
If oJson:GetJsonText("level") == "null" .Or. Len(oJson["level"]) == 0
aCab := {'Janeiro', 'Fevereiro', 'Março' }
aData1 := { Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ) }
aData2 := { Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ) }
aData3 := { Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ) }
aData4 := { Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ) }
oCoreDash:SetChartInfo( aData1, 'Vendedor 01',,aCores[8][3] ) //Cor utilizada: OrangeLht
oCoreDash:SetChartInfo( aData2, 'Vendedor 02',,aCores[1][3] ) //Cor utilizada: GreenDk
oCoreDash:SetChartInfo( aData3, 'Vendedor 03',,aCores[6][3] ) //Cor utilizada: YellowDk
oCoreDash:SetChartInfo( aData4, 'Vendedor 04',,aCores[15][3] ) //Cor utilizada: BrowDk
nSaldo := (aData1[1] + aData2[1] + aData3[1] + aData4[1] ) / 4
aAdd(aSaldo, nSaldo)
nSaldo := (aData1[2] + aData2[2] + aData3[2] + aData4[2] ) / 4
aAdd(aSaldo, nSaldo)
nSaldo := (aData1[3] + aData2[3] + aData3[3] + aData4[3] ) / 4
aAdd(aSaldo, nSaldo)
oCoreDash:SetChartInfo( aSaldo, 'Média', 'line', aCores[9][3] ,,.F.) //Cor utilizada: BlueDk
aDataFim := {}
aAdd(aDataFim, oCoreDash:SetChart(aCab,,.T.))
ElseIf Len(oJson["level"]) == 1
aCab := {'Semana 1', 'Semana 2', 'Semana 3', 'Semana 4' }
aData1 := { Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 )}
aData2 := { Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 )}
aData3 := { Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 )}
aData4 := { Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 )}
aData5 := { Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 ), Randomize( 100000000.00, 999000000.00 )}
oCoreDash:SetChartInfo( aData1, '00000101 - Cliente 000001',,aCores[8][3] ) //Cor utilizada: OrangeLht
oCoreDash:SetChartInfo( aData2, '00000102 - Cliente 000002',,aCores[1][3] ) //Cor utilizada: GreenDk
oCoreDash:SetChartInfo( aData3, '00543501 - Cliente 000003',,aCores[6][3] ) //Cor utilizada: YellowDk
oCoreDash:SetChartInfo( aData4, '00543502 - Cliente 000004',,aCores[15][3] ) //Cor utilizada: BrowDk
oCoreDash:SetChartInfo( aData5, '00543503 - Cliente 000005',,aCores[10][3] ) //Cor utilizada: BlueLht
aDataFim := {}
aAdd(aDataFim, oCoreDash:SetChart(aCab,,.T., ,"Maiores Vendas - " + oJson["level"][1]["labelDataSet"] + " - " + oJson["level"][1]["label"]))
ElseIf Len(oJson["level"]) == 2
aCab := {"Pedido - 234323", "Pedido - 234322", "Pedido - 234456", "Pedido - 234533", "Pedido - 234222" }
oData := JsonObject():New()
aData := { 26589, 25000,23560,10000,35000}
aDataFim := {}
aAdd(aDataFim, oCoreDash:SetChart(aCab, aData, .T.,"pie", "Maiores Clientes - " + oJson["level"][2]["labelDataSet"] + " - " + oJson["level"][1]["label"]))
EndIf
oResponse["items"] := aDataFim
Return
//-------------------------------------------------------------------
/*/{Protheus.doc} GET itemsDetails
Método para retornar os dados do Painel
@author Squad CRM & Faturamento
@since 27/03/2020
@version Protheus 12.1.27
/*/
//-------------------------------------------------------------------
WSMETHOD POST itemsDetails WSRECEIVE JsonFilter, drillDownFilter WSRESTFUL Exemplo3
Local aHeader := {}
Local aItems := {}
Local aRet := {}
Local cBody := DecodeUtf8(Self:GetContent())
Local cError := "Erro na Requisição"
Local lRet := .T.
Local oCoreDash := CoreDash():New()
Local oBody := JsonObject():New()
Local oJsonFilter := JsonObject():New()
Local oJsonDD := JsonObject():New()
If !Empty(cBody)
oBody:FromJson(cBody)
If ValType(oBody["chartFilter"]) == "J"
oJsonFilter := oBody["chartFilter"]
EndIf
If ValType(oBody["detailFilter"]) == "A"
oJsonDD := oBody["detailFilter"]
EndIf
EndIf
Self:SetContentType("application/json")
//Verifico o Nivel do grafico
If oJsonFilter:GetJsonText("level") == "null" .Or. Len(oJsonFilter["level"]) == 0
//Verifico o nivel do Drilldpwn
If Len(oJsonDD) == 0
aHeader := {;
{"codigo" , "Código" ,"link" },;
{"nome" , "Nome Vendedor" },;
{"totalItens" , "Total de Itens","number",'1.2-5',.F. },;
{"totalValor" , "Valor Total" , "currency","BRL",.F.};
}
aItems := {;
{"codigo" , "SA3.A3_COD" },;
{"nome" , "SA3.A3_NOME" },;
{"totalItens" , "QTDITEM" },;
{"totalValor" , "TOTAL","N" };
}
aRet := MntQuery1()
ElseIf Len(oJsonDD) == 1
//Caso eu queira pegar o nome do nível selecionado : oJsonFilter["level"][1]["labelDataSet"]
// Se fosse gráfico do tipo pizza: oJsonFilter["level"][1]["label"]
aHeader := {;
{"codigoPed" , "Código do Pedido" },;
{"codigoCli" , "Código do Cliente" },;
{"nome" , "Nome" },;
{"totalValor" , "TOTAL","currency","BRL",.F.};
}
aItems := {;
{"codigoPed" , "SC5.C5_NUM" },;
{"codigoCli" , "SC5.C5_CLIENTE" },;
{"nome" , "SA1.A1_NOME" },;
{"totalValor" , "TOTAL","N" };
}
aRet := MntQuery2("SC5.C5_VEND1 = '" + oJsonDD[1]["codigo"] + "'")
EndIf
ElseIf Len(oJsonFilter["level"]) == 1
aHeader := {;
{"codigo" , "Código" },;
{"nome" , "Nome Vendedor" },;
{"totalItens" , "Total de Itens","number",'1.2-5',.F.},;
{"totalValor" , "Valor Total", "currency","BRL",.F.};
}
aItems := {;
{"codigo" , "SA3.A3_COD" },;
{"nome" , "SA3.A3_NOME" },;
{"totalItens" , "QTDITEM" },;
{"totalValor" , "TOTAL","N" };
}
aRet := MntQuery1()
EndIf
oCoreDash:SetQuery(aRet[1])
oCoreDash:SetWhere(aRet[2])
oCoreDash:SetGroupBy(aRet[3])
oCoreDash:SetFields(aItems)
oCoreDash:SetApiQstring(Self:aQueryString)
oCoreDash:BuildJson()
If lRet
oCoreDash:SetPOHeader(aHeader)
Self:SetResponse( oCoreDash:ToObjectJson() )
Else
cError := oCoreDash:GetJsonError()
SetRestFault( 500, EncodeUtf8(cError) )
EndIf
oCoreDash:Destroy()
FreeObj(oBody)
FreeObj(oJsonFilter)
FreeObj(oJsonDD)
FreeObj(oCoreDash)
aSize(aRet, 0)
aSize(aItems, 0)
aSize(aHeader, 0)
Return( lRet )
//-------------------------------------------------------------------
/*/{Protheus.doc} MntQuery1
Monta a Query o Total dos Pedidos de Venda
@author Squad CRM & Faturamento
@since 27/03/2020
@version Protheus 12.1.27
/*/
//-------------------------------------------------------------------
Static Function MntQuery1()
Local cQuery := ""
Local cWhere := ""
Local cGroup := ""
cQuery := " SELECT SA3.A3_COD, SA3.A3_NOME, COUNT(C6_ITEM) QTDITEM, SUM(C6_VALOR) TOTAL "
cQuery += " FROM " + RetSqlName("SC5") + " SC5 "
cQuery += " INNER JOIN " + RetSqlName("SC6") + " SC6 ON SC6.C6_NUM = SC5.C5_NUM "
cQuery += " INNER JOIN " + RetSqlName("SA3") + " SA3 ON SA3.A3_COD = SC5.C5_VEND1 "
cWhere := " SC5.D_E_L_E_T_ = ' ' "
cWhere += " AND SC6.D_E_L_E_T_ = ' ' "
cWhere += " AND SA3.D_E_L_E_T_ = ' ' "
cWhere += " AND SC5.C5_FILIAL = '" + xFilial("SC5") + "' "
cWhere += " AND SC6.C6_FILIAL = '" + xFilial("SC6") + "' "
cWhere += " AND SA3.A3_FILIAL = '" + xFilial("SA3") + "' "
cGroup := " SA3.A3_COD, SA3.A3_NOME "
Return {cQuery, cWhere, cGroup}
//-------------------------------------------------------------------
/*/{Protheus.doc} MntQuery2
Monta Query Pedido de vendas
@author Squad CRM & Faturamento
@since 27/03/2020
@version Protheus 12.1.27
/*/
//-------------------------------------------------------------------
Static Function MntQuery2(cFilter)
Local cQuery := ""
Local cGroup := ""
Local cWhere := ""
Default cFilter := ""
cQuery := " SELECT SC5.C5_NUM, SC5.C5_CLIENTE, SA1.A1_NOME, SUM(C6_VALOR) TOTAL "
cQuery += " FROM " + RetSqlName("SC5") + " SC5 "
cQuery += " INNER JOIN " + RetSqlName("SC6") + " SC6 ON SC6.C6_NUM = SC5.C5_NUM "
cQuery += " INNER JOIN " + RetSqlName("SA1") + " SA1 ON SA1.A1_COD = SC5.C5_CLIENTE
if !Empty(cFilter)
cWhere += cFilter + " AND "
EndIf
cWhere += " SC5.D_E_L_E_T_ = ' ' "
cWhere += " AND SC6.D_E_L_E_T_ = ' ' "
cWhere += " AND SA1.D_E_L_E_T_ = ' ' "
cWhere += " AND SC5.C5_FILIAL = '" + xFilial("SC5") + "' "
cWhere += " AND SC6.C6_FILIAL = '" + xFilial("SC6") + "' "
cWhere += " AND SA1.A1_FILIAL = '" + xFilial("SA1") + "' "
cGroup := " C5_NUM, C5_CLIENTE, SA1.A1_NOME "
Return {cQuery, cWhere, cGroup}
|
|
|
