Integração padrão de arquivo texto. Utilizado durante a rotina de integração de arquivo texto para o SIGAEIC.
User Function IN100CLI()
Local cParamIXB
Local nPosCod
Local cLote
Begin Sequence
If ValType(ParamIXB) == "A"
cParamIXB:= ParamIXB[1]
Else
cParamIXB:= ParamIXB
EndIf
Do Case
Case cParamIXB == "DELDESP"
/*
Possibilita intervir na integração das despesas, impedindo que ocorra a exclusão
*/
lDeletaSWD:= .F.
Case cParamIXB == "VALFD"
cErro := nil
Int_FE->NFEINT_OK := "T"
Case cParamIXB == "VALFE"
cLote:= Int_FD->NFDLOTECTL
//Exemplo para incluir uma nova informação no arquivo txt e gravar essas informações nas tabelas SWN e SD1.
//Para isso vamos utilizar em conjunto os pontos de entrada "FD","GRVFD" e "GRVFD1"
//neste exemplo vamos utilizar os campos da fecp, mas pode ser qualquer outro campo
Case cParamIXB == "FD"
AADD(aEstruDef,{"NFALFECP" ,"N",6,2}) //Adiciona os campos novos no array da estrutura para que consiga ler as informações do arquivo txt
AADD(aEstruDef,{"NFVLFECP" ,"N",9,2})
//Este ponto de entrada também pode ser utilizado para alterar o tamanho de um campo
nPosCod := aScan(aEstruDef,{|x| AllTrim(x[1])=="NFDFATURA"})
aEstruDef[nPosCod][3]:=20 //altera o tamanho do campo NFDFATURA
nPosCod := aScan(aEstruDef,{|x| AllTrim(x[1])=="NFDLOTECTL"})
aEstruDef[nPosCod][3]:=20 //altera o tamanho do campo LOTE
Case cParamIXB == "GRVFD" //Grava o valor dos campos novos na tabela SWN
SWN->WN_ALFECP := INT_FD->NFALFECP
SWN->WN_VLFECP := INT_FD->NFVLFECP
Case cParamIXB == "GRVFD1" // Adiciona os campos novos no array aItens para que sejam gravados na tabela SD1
AADD(aItens[len(aItens)],{"D1_ALQFECP" ,INT_FD->NFALFECP ,NIL})
AADD(aItens[len(aItens)],{"D1_VALFECP" ,INT_FD->NFVLFECP ,NIL})
EndCase
End Sequence
Return |
| Ação | Descrição |
|---|---|
| DELDESP | Parâmetro que indica o processamento da integração das despesas. Chamado antes do processsamento de exclusão. |
| VALFD | Parâmetro que indica o processamento da integração de nota fiscal. |
| VALFE | Parâmetro que indica o processamento da integração de nota fiscal. |
| GRVFD | Parâmetro que permite manipular a gravação dos dados na tabela SWN. |
| GRVFD1 | Parâmetro que permite manipular a gravação dos dados na tabela SD1. |
| FD | Parâmetro que permite manipular a estrutura de dados de leitura dos itens do arquivo txt que está sendo integrado. |
| Parâmetro | Nome | Tipo | Pode alterar | Descrição |
|---|---|---|---|---|
| DELDESP | lDeletaSWD | Lógico | Sim | Disponível no ponto de entrada com o parâmetro DELDESP, possibilita intervir na exclusão da despesa recebida pela integração padrão, permitindo ou bloqueando a operação. |
| VALFD | cErro | Caracter | Sim | Quando atualizado para nil permite passar pela validação da LI quando o item não é anuente e foi informada a LI no arquivo texto. |
| VALFD | Int_FE->NFEINT_OK | Caracter | Sim | Quando atualizado para = "T" indica que as validações do item estão ok, deve ser utilizado em conjunto com a variável cErro. |
| VALFE | Int_FD | Work | Não | Work disponível para consultar os itens integrados na nota fiscal, já com a quebra por lote quando for o caso. |
| GRVFD | SWN | Tabela | Sim | Disponibiliza os campos da tabela SWN |
| GRVFD1 | aItens | Array | Sim | Permite alterar os dados a serem enviados na integração para a tabela de itens da nota (SD1) |
| FD | aEstruDef | Array | Sim | Permite manipular a estrutura de dados que irá gravar os itens da nota fiscal. |
Não há.