MRPEDITEXP - Alterar informações dos produtos na exportação dos resultados do MRP

Linha de Produto:

Protheus

Segmento:

Manufatura

Módulo:

SIGAPCP - Planejamento e Controle da Produção

Parâmetro(s):

NomeTipoDescriçãoDefaultObrigatórioReferência
PARAMIXB[1]CaracterTicket do MRP.


PARAMIXB[2]JsonObjeto Json com as informações dos produtos que serão exportados.

X

Idiomas:

Todos

País(es):

Todos

Banco(s) de Dados:

Todos

Sistema(s) Operacional(is):

Todos

Ponto de Entrada

Descrição:O ponto de entrada MRPEDITEXP permite o usuário realizar alterações nos campos de produto no arquivo Excel dos resultados do MRP.
Localização:

Função getProds do fonte MRPData, chamada pela ação "Exportar Excel" da tela Resultados MRP (em Po UI).

Eventos:

Permite que sejam manipuladas as informações dos produtos a serem exportadas no o arquivo Excel.

Programa Fonte:MRPData.prw

Sintaxe:

MRPEDITEXP()

Retorno:

Nil

Observações:

O parâmetro 2 (oJson) é um objeto Json que possui o cabeçalho oJson["headers"] ordenados conforme a ordem de exportação e os itens oJson["items"].


Exemplo

#Include "Totvs.ch"

//Ponto de Entrada para alterar as informações dos produtos que estão sendo exportados
User Function MRPEDITEXP()
    Local cAliasQry  := GetNextAlias()
	Local cTicket    := ParamixB[1]
	Local oJson      := ParamixB[2]
	Local nIndex     := 1
	Local nLenHeader := Len(oJson["headers"])
	Local nLenItems  := Len(oJson["items"])

	aAdd(oJson["headers"], JsonObject():New())
	nLenHeader++
	oJson["headers"][nLenHeader]["id"]    := "especifico"
	oJson["headers"][nLenHeader]["label"] := "Cabeçalho Específico"

	aAdd(oJson["headers"], JsonObject():New())
	nLenHeader++
	oJson["headers"][nLenHeader]["id"]    := "level"
	oJson["headers"][nLenHeader]["label"] := "Nível"

	For nIndex := 1 To nLenItems
		cProduto := oJson["items"][nIndex]["productId"]

		BeginSql Alias cAliasQry
			SELECT MAX(HWB_NIVEL) Nivel
			  FROM %Table:HWB%
			 WHERE HWB_TICKET = %exp:cTicket%
			   AND HWB_PRODUT = %exp:cProduto%
			   AND %NotDel%
		EndSql

		oJson["items"][nIndex]["especifico"] := "Valor Específico"
		oJson["items"][nIndex]["level"]      := (cAliasQry)->Nivel

		(cAliasQry)->(dbCloseArea())
	Next nIndex

Return