P200ADBUT - Adiciona botões em "Outras Ações" do cadastro da estrutura

Linha de Produto:

Protheus

Segmento:

Manufatura

Módulo:

SIGAPCP - Planejamento e Controle da Produção

Parâmetro(s):

Nenhum

Idiomas:

Todos

País(es):

Todos

Banco(s) de Dados:

Todos

Sistema(s) Operacional(is):

Todos

Ponto de Entrada

Descrição:
O ponto de entrada P200ADBUT permite que sejam incluídas novas ações dentro das operações de Inclusão e Alteração da estrutura pelo PCPA200.
Localização:

Function ViewDef - Definição da view do PCPA200.

Eventos:

O ponto de entrada é chamado ao selecionar uma operação no PCPA200, durante a criação da view.

Programa Fonte:PCPA200.PRW

Sintaxe:

P200ADBUT ( ) --> aButtons

Retorno:

aButtons: Array com os botões a serem adicionados nas operações de Inclusão e Alteração:

aButtons[n][1] := Título do botão

aButtons[n][2] := Bloco de código a ser executado ao clicar no botão

Observações:

Os novos botões só serão criados nas operações: Incluir e Alterar.

#INCLUDE "TOTVS.CH"
#INCLUDE "FWMVCDEF.CH"

User Function P200ADBUT()
	Local aButtons := {}
	/*
		Estrutura do array de retorno:
			aButtons[n][1] := Título do botão
			aButtons[n][2] := Bloco de código a ser executado ao clicar no botão
	*/
	aAdd(aButtons, {"Mensagem OK"   , {|| botao1()}          })
	aAdd(aButtons, {"Operação atual", {|oView| botao2(oView)}})

Return aButtons

Static Function botao1()

	Alert("OK!")

Return

Static Function botao2(oView)
	Local oModel   := oView:GetModel()
	Local cProduto := oModel:GetModel("SG1_MASTER"):GetValue("G1_COD")

	If oModel:GetOperation() == MODEL_OPERATION_UPDATE
		Alert("Você está alterando a estrutura do produto " + cProduto)
	ElseIf oModel:GetOperation() == MODEL_OPERATION_INSERT
		Alert("Você está incluindo uma nova estrutura")
	EndIf

Return