01. DADOS GERAIS

Linha de Produto:Microsiga Protheus®
Segmento:Logística
Módulo:SIGATMS - Gestão de Transportes 


02. DESCRIÇÃO

Ponto de entrada que permite alterar a condição de igualdade das informações entre o que foi informado na cotação e o que foi digitado na nota fiscal. Foi criado pois quando alterado o valor informado da nota fiscal, este valor não é comparado pela rotina padrão.

03. EXEMPLO DE UTILIZAÇÃO

Parâmetros:

Nome

Tipo

Descrição

Default

Obrigatório

Referência

lIgualCot

Logic

Condição de igualdade definida por padrão









cSeekDT4

Character

Chave para leitura da cotação de frete









Retorno:

lRet


Retorno será uma variável lógica contendo .T. ou .F. para alterar a condição de igualdade definida no fonte padrão.

Variáveis:

Nome

Tipo

Escopo

Pode Alterar

Descrição




Logic

Local

Sim


Programa Fonte
TMSA200.PRW

Sintaxe 
TM200IGU - Permite alterar a condição de igualdade entre cotação e nota fiscal ( [ lIgualCot,cSeekDT4 ] ) --> aRet    

#Include "Protheus.ch"

User Function TM200IGU()
Local lIgualCot := ParamIXB[1]
Local cSeekDT4  := ParamIXB[2]
Local lRet      := lIgualCot
Local nDTCVInf  := 0
Local nDF1VInf  := 0
Local aAreas    := {DF1->(GetArea()),DT4->(GetArea()),DT5->(GetArea()),GetArea()}

If lIgualCot
	DT4->(DbSetOrder(1))
	If DT4->(DbSeek(cSeekDT4))
		DT5->(DbSetOrder(5))
		If DT5->(DbSeek(xFilial("DT5") + DT4->(DT4_FILORI + DT4_NUMCOT)))
			DTC->(DbSetOrder(8))
			If DTC->(DbSeek(xFilial("DTC") + DT5->(DT5_FILORI + DT5_NUMSOL)))
				nDTCVInf := DTC->DTC_VLRINF
			EndIf
	
			DF1->(DbSetOrder(2))
			If DF1->(DbSeek(xFilial("DF1") + DT4->(DT4_FILORI + DT4_NUMCOT)))
				nDF1VInf := DF1->DF1_VLRINF
			EndIf

			lRet := nDTCVInf == nDF1VInf
		EndIf
	EndIf
EndIf

AEval(aAreas,{|x,y| RestArea(x),FwFreeArray(x)})

Return lRet


04. DEMAIS INFORMAÇÕES

Não há.

05. ASSUNTOS RELACIONADOS

Não há.



<style>
div.theme-default .ia-splitter #main {
    margin-left: 0px;
}
.ia-fixed-sidebar, .ia-splitter-left {
    display: none;
}
#main {
    padding-left: 10px;
    padding-right: 10px;
    overflow-x: hidden;
}

.aui-header-primary .aui-nav,  .aui-page-panel {
    margin-left: 0px !important;
}
.aui-header-primary .aui-nav {
    margin-left: 0px !important;
}
</style>