A função que carrega carrega a lista de Motivos de Baixa é utilizada internamento em diversos pontos do sistema, tanto do Financeiro como de outros módulos. Portanto, é importante fazer o uso correto aplicando o filtro especificamente a rotina/processo que deseja contemplar, conforme sua regra de negócio; caso contrário, o filtro aplicado poderá deixar de carregar Motivos de Baixa reservados para outros processos do ERP.

#INCLUDE "PROTHEUS.CH"
 
User Function FILMOTBX()
 
    Local nX       As Numeric
    Local aArea    As Array
    Local aMotBx   As Array
    Local aNewMotR As Array
        
    aMotBx   := aClone(ParamIXB)//Motivos listados da F7G
    aArea    := GetArea()
    aNewMotR := {}

    //Só apresenta lista de Motivos de Baixa com movimentação bancária, na rotina de baixas da carteira Receber
    If FwIsInCallStack('FINA070')
        
        dbSelectArea('F7G')
        dbSetOrder(1)        
        For nX:=1 to Len(aMotBx)
            //Pesquisa pela Sigla do Motivo de Baixa
            dbSeek( FWxFilial('F7G') + Substr(aMotBx[nX],1,3) )
            If F7G_MOVBCO == 'S' 
                AADD( aNewMotR, aMotBx[nX] )         
            EndIF
        Next nX
    Else
        //Retorna lista completa
        aNewMotR := aClone(aMotBx)           
    EndIf

    RestArea(aArea)
    FwFreeArray(aMotBx)
    FwFreeArray(aArea)
 
Return aNewMotR