Exibir origem

CONTEÚDO

Visão Geral
Exemplo de Utilização
Rotina Automática
Principais Campos
Pré-condições para Utilização da Rotina
Tabelas Utilizadas
Assuntos Relacionados

01. VISÃO GERAL

O cadastro de Correlação de Produtos contém os produtos que serão listados na geração da obrigação acessória EFD ICMS/IPI no registro 0221 do Bloco K.

A rotina permite a informação de N códigos correlacionados com os registros da tabela Produtos (SB1), com suas respectivas quantidades.

02. EXEMPLO DE UTILIZAÇÃO

Na página principal da rotina, estão disponíveis as opções:

Permite a inclusão de informações de um produto.

As informações devem ser preenchidas conforme as orientações descritas em Principais Campos.

Cadastrar um Registro

1. No módulo SIGAEST, acesse Atualizações → Cadastros → Produto → Correlação de Produtos
2. Na tela Correlação de Produtos, clique em Incluir.
3. Na tela Filiais, selecione o código da Filial.
4. Na tela Correlação de Produtos - Incluir, informe os dados necessários para o cadastro em questão, definindo os dados do produto pai e produtos filhos.
5. Clique em Confirmar.

Permite a alteração de informações do produto selecionado.

As informações devem ser ajustadas conforme as orientações descritas em Principais Campos.

Alterar as Informações do Registro Cadastrado

1. Na tela Correlação de Produtos, selecione o registro cujas informações serão alteradas.
2. Clique em Alterar.
3. Na tela Correlação de Produtos - Alterar, efetue a alteração necessária.
4. Clique em Confirmar.

Permite a visualização de informações do produto.

Visualizar um Registro Cadastrado

1. Na tela Correlação de Produtos, selecione o registro cujas informações serão eliminadas.
2. Clique em Outras Ações → Visualizar.
3. Em seguida será apresentada uma mensagem solicitando a confirmação da exclusão.
4. Clique em Confirmar.

Permite a exclusão um produto.

Excluir um Registro Cadastrado

1. Na tela Correlação de Produtos, selecione o registro cujas informações serão eliminadas.
2. Clique em Outras Ações → Excluir.
3. Em seguida será apresentada uma mensagem solicitando a confirmação da exclusão.
4. Clique em Confirmar.

03. ROTINA AUTOMÁTICA

A rotina Correlação de Produtos permite a efetuação das operações por meio de rotina automática em MVC que podem ser utilizadas em suas customizações conforme exemplos abaixo:

#INCLUDE "RWMAKE.CH" 
#INCLUDE "TBICONN.CH"
#INCLUDE 'Protheus.ch'
#INCLUDE 'FWMVCDef.ch'
//------------------------------------------------------------------------
/*
EXEMPLO DE INCLUSÃO
*/
//------------------------------------------------------------------------
User Function m039Inc()
Local oModel      := Nil
Private lMsErroAuto := .F.
 
PREPARE ENVIRONMENT EMPRESA "99" FILIAL "01" MODULO "EST"
 
    oModel := FwLoadModel("MATA039")
    oModel:SetOperation(MODEL_OPERATION_INSERT)
    oModel:Activate()
    // Cabeçalho
    oModel:SetValue("MdFieldD4C", "D4C_PRODUT", "001")
    // Item 01
    oModel:SetValue("MdGridD4C", "D4C_PRDATO", "002")
    oModel:SetValue("MdGridD4C", "D4C_QTPRAT", 5)
    oModel:GetModel("MdGridD4C"):AddLine()
    // Item 02
    oModel:SetValue("MdGridD4C", "D4C_PRDATO", "003")
    oModel:SetValue("MdGridD4C", "D4C_QTPRAT", 10)

    If oModel:VldData()
        oModel:CommitData()
        MsgInfo("Registro INCLUIDO!", "Atenção")
    Else
        VarInfo("",oModel:GetErrorMessage())
    EndIf       
        
    oModel:DeActivate()
    oModel:Destroy()

    oModel := NIL

RESET ENVIRONMENT

Return Nil

//------------------------------------------------------------------------
/*
EXEMPLO DE ALTERAÇÃO
*/
//------------------------------------------------------------------------
User Function m019Alt()
Local oModel := Nil
Local cProdPai := "001                           "
Local cProdFil := "002                           "
Private lMsErroAuto := .F.
 
PREPARE ENVIRONMENT EMPRESA "99" FILIAL "01" MODULO "EST"
 
// Posiciona
D4C->(DbSetOrder(1))
If D4C->(DbSeek(xFilial("D4C") + cProdPai + cProdFil))
    oModel := FwLoadModel("MATA039")
    oModel:SetOperation(MODEL_OPERATION_UPDATE)
    oModel:Activate()
    oModel:SetValue("MdGridD4C","D4C_QTPRAT",15)
 
    If oModel:VldData()
        oModel:CommitData()
        MsgInfo("Registro ALTERADO!", "Atenção")
    Else
        VarInfo("",oModel:GetErrorMessage())
    EndIf
    
    oModel:DeActivate()
Else
    MsgInfo("Registro NAO LOCALIZADO!", "Atenção")
EndIf

RESET ENVIRONMENT

Return Nil

//------------------------------------------------------------------------
/*
EXEMPLO DE EXCLUSÃO
*/
//------------------------------------------------------------------------
User Function m019Exc()
Local oModel := Nil
Local cProdPai := "001                           "
Local cProdFil := "002                           "
Private aRotina := {}
 
PREPARE ENVIRONMENT EMPRESA "99" FILIAL "01" MODULO "EST"

// Posiciona
D4C->(DbSetOrder(1))
If D4C->(DbSeek(xFilial("D4C") + cProdPai + cProdFil))
    oModel := FwLoadModel ("MATA039")
    oModel:SetOperation(MODEL_OPERATION_DELETE)
    oModel:Activate()
 
    If oModel:VldData()
        oModel:CommitData()
        MsgInfo("Registro EXCLUIDO!", "Atenção")
    Else
        VarInfo("",oModel:GetErrorMessage())
    EndIf

    oModel:DeActivate()
Else
    MsgInfo("Registro NAO LOCALIZADO!", "Atenção")
EndIf

RESET ENVIRONMENT
 
Return Nil

04. PRINCIPAIS CAMPOS

Na tela de cadastro da rotina, estão disponíveis as opções:

No cabeçalho são informados os dados de identificação do produto pai.

Campo:	Descrição
Codigo do Produto Pai	Informe o código identificador do produto pai.
Un. de medida Prod Pai	Unidade de medida do produto pai obtido a partir da tabela Produtos (SB1), preenchido automaticamente após definição do código do produto pai.

Nos itens são informados os dados de identificação dos produtos filhos.

Campo:	Descrição
Codigo Produto Filho	Informe o código identificador do produto filho que será correlacionado com o produto pai.
Unid. de medida Prd Filho	Unidade de medida do produto filho obtido a partir da tabela Produtos (SB1), preenchido automaticamente após definição do código do produto filho.
Quant. Prod. Filho	Informe a quantidade do produto filho.