Descripción

El punto de entrada FI040MNCP se utiliza para manejar las columnas del aBrowse de la rutina de Consulta de títulos por cobrar (FINC040).

Vea también

Para cumplir con la Ley general de protección de datos (Ley n° 13.70), algunos campos que muestran informaciones consideradas como datos sensibles, se ocultarán y dejarán de ser legibles.
Para tratar la ocultación de campos modificados por este punto de entrada, utilice el Punto de entrada FI040CPCO .

Condición previa

La ejecución del PE FI040MNCP está condicionada a la presencia de los siguientesos PE:

FI040TPCP - Define los tipos de columnas incluidas en aBrowse

FI040GRCP - Graba los campos incluidos en aBrowse

Ejemplos


#INCLUDE "PROTHEUS.CH"
 
//----------------------------------------------------------------------------------
/*/{Protheus.doc} FI040MNCP
Maneja las columnas del aBrowse en la rutina de Consulta de títulos por cobrar (FINC040).

@return aBrowPE[1] = Nombre de la columna que se mostrará en la pantalla.
		aBrowPE[2] = Campo de la tabla SE5 que se incluirá.
/*/
//----------------------------------------------------------------------------------

User FUNCTION FI040MNCP()
    LOCAL aBrowPE := PARAMIXB[1] // Array para manejarse
 
    IF EMPTY(aBrowPE)
        aBrowPE:= {;
            {" ","OK"},; //Led de activo, anulado o revertido
            {STR0010,"DATAX"},; //Fecha
            {STR0011,"JUROS"},; //Intereses
            {STR0012,"MULTA"},; //Multa
            {STR0013,"CORRECAO"},; //Corrección
            {STR0014,"DESCONTOS"},; //Descuentos
            {STR0101,"VALACESS"},; //Valores accesorios
            {STR0106,"VALORTRANS"},;//Valor descontado
            {STR0015,"VALORRECEB"},;//Valor cobrado
            {STR0016,"MOTIVO"},; //Motivo
            {STR0017,"HISTORICO"},; //Historial
            {STR0018,"DATACONT"},; //Fecha de la contabilidad
            {STR0090,"DATADISP"},; //Fecha de la contabilidad
            {STR0019,"LOTE"},; //Lote
            {STR0020,"BANCO"},; //Banco
            {STR0021,"AGENCIA"},; //Agencia
            {STR0022,"CONTA"},; //Cuenta
            {STR0023,"DOCUMENTO"},; //Documento
            {STR0081,"FILIAL"},; //Sucursal Movto.
            {STR0082,"RECONC"},; //Conciliado
            {"ID","IDORIG"};
        }
    ENDIF

    IF ASCAN(aBrowPE,{|e| e[2] $ 'E5_BENEF' }) == 0
        AADD(aBrowPE,{"Campo1","E5_BENEF"}) // Campo 1 incluido por el cliente
    ENDIF

    IF ASCAN(aBrowPE,{|e| e[2] $ 'E5_AUTBCO' }) == 0
        AADD(aBrowPE,{"Campo2","E5_AUTBCO"}) // Campo 2 incluido por el cliente
    ENDIF
 
RETURN aBrowPE


Idioma

Portugués(Brasil)

Versiones

Microsiga_Protheus11

Sistemas operativos compatibles

Todos

Compatible con las bases de datos

Todas

Devolución

aBrowPE - retorna array con las columnas manejadas

Variables

aBrowPE - retorna array con las columnas manejadas

Programa fuente

FINC040.PRX