TOTVSTEC

Árvore de páginas

O método adiciona um cabeçalho HTTP à lista de cabeçalhos que serão enviados na mensagem SOAP destinada ao servidor WSDL.

Sintaxe

AddHttpHeader( < cName >, < cValue > )

Parâmetros

Nome

Tipo

Descrição

Obrigatório

Referência

cName

caractere

Nome do cabeçalho que será adicionado.

X


cValue

caractere

Valor do cabeçalho que será adicionado.

X


Retorno

Nome

Tipo

Descrição

lRet

lógico

Verdadeiro (.T.) caso consiga adicionar. Falso (.F.) caso contrário.

Observações

  • O valor passado em cName deve ter conteúdo.
  • Se cValue for passado vazio, o cabeçalho não será enviado.
  • Esse método deve ser chamado após o método SetOperation.
  • Esse método deve ser chamado antes de SendSoapMsg.

Exemplos

Exemplo 1
User Function Teste()
  Local oWsdl
  Local xRet
  
  // Cria o objeto da classe TWsdlManager
  oWsdl := TWsdlManager():New()
  
  // Faz o parse de uma URL
  xRet := oWsdl:ParseURL( "http://wsf.cdyne.com/WeatherWS/Weather.asmx?WSDL" )
  if xRet == .F.
    conout( "Erro: " + oWsdl:cError )
    Return
  endif
  
  // Define a operação
  xRet := oWsdl:SetOperation( "GetCityForecastByZIP" )
  if xRet == .F.
    conout( "Erro: " + oWsdl:cError )
    Return
  endif
  
  // Define o valor de cada parâmeto necessário
  xRet := oWsdl:SetValue( 0, "90210" )
  if xRet == .F.
    conout( "Erro: " + oWsdl:cError )
    Return
  endif
  
  // Adiciona cabeçalho aos cabeçalhos HTTP que serão enviados
  xRet := oWsdl:AddHttpHeader( "Pragma", "no-cache" )
  if xRet == .F.
    Return
  endif
  
  // Envia a mensagem SOAP ao servidor
  xRet := oWsdl:SendSoapMsg()
  if xRet == .F.
    conout( "Erro: " + oWsdl:cError )
    Return
  endif
Return



  • Sem rótulos