Converte uma informação do tipo caractere, data, lógico ou numérico para string, sem adição de espaços na informação.
cValToChar( < xParametro > )
Nome | Tipo | Descrição | Obrigatório | Referência |
|---|---|---|---|---|
xParametro | qualquer | Indica um valor do tipo caractere, data, lógico ou numérico para converter em string. | X |
|
Nome | Tipo | Descrição |
|---|---|---|
cRet | caractere | Retorna uma string de acordo com o valor e tipo do parâmetro informado. |
Para cada tipo de informação a função realizará a seguinte conversão:
Caractere: Retorna a própria string passada.
Data: Retorna uma string contendo a data de acordo com o valor em <cValToChar>, retornando no mesmo formato que a data foi passada.
Lógico: Retorna uma string '.T.' se o valor lógico for verdadeiro ou '.F.' se o valor lógico for falso.
Numérico: Retorna uma string com o número informado. No entanto, observe que um valor inteiro suporta até 16 casas de precisão caso seja um fracionário com 16 casas tanto na parte inteira como na decimal.
Para outros tipos de dados, o retorno será uma string vazia.
#DEFINE CRLF Chr(13)+Chr(10)
User Function Exemplo()
Local aArray := {.T., .F.}
Local bBloco := {|| .T.}
Local cCaractere := "Caractere", cMensagem := ""
Local dData := Date()
Local lLogico := .T.
Local nNumerico := 1024.2048
Local oObjeto := MSDialog():Create()
Local uUndefined := Nil
//+----------------------------------------------------------------------------+
//|Exemplifica o uso da função cValToChar |
//+----------------------------------------------------------------------------+
cMensagem += "[" + cValToChar(aArray) + "] Array" + CRLF
cMensagem += "[" + cValToChar(bBloco) + "] Bloco de código" + CRLF
cMensagem += "[" + cValToChar(cCaractere) + "] Caractere" + CRLF
cMensagem += "[" + cValToChar(dData) + "] Data" + CRLF
cMensagem += "[" + cValToChar(lLogico) + "] Lógico" + CRLF
cMensagem += "[" + cValToChar(nNumerico) + "] Numérico" + CRLF
cMensagem += "[" + cValToChar(uUndefined) + "] Undefined"
//+----------------------------------------------------------------------------+
//|Apresenta uma mensagem com os resultados obtidos |
//+----------------------------------------------------------------------------+
Return MsgInfo(cMensagem, "Exemplo do cValToChar")
Microsiga Protheus 8.11 , Protheus 10 , TOTVS Application Server 10 , ByYou Application Server