Linha Microsiga Protheus

Page tree


Descrição:

Permite incluir campos adicionais relacionados à Carga na tela de seleção de pedidos da Montagem de Carga.

Localização:

Localizado na função que monta a estrutura da tela de Montagem de Carga.

Parâmetros:

NomeTipoDescrição

oCargas

ObjetoObjeto do tipo ListBox, que contém a estrutura da grid de Cargas
aArrayCargaArrayContém as informações da Carga que está sendo montada
aHeadersArray

Contém o cabeçalho dos campos a serem apresentados na grid de Cargas

bLineBloco de CódigoArmazena a regra de preenchimento dos campos da grid de Cargas
oEnableObjetoContém a imagem/ícone a ser apresentada quando o registro da carga estiver Habilitado
oDisableObjetoContém a imagem/ícone a ser apresentada quando o registro da carga estiver Desabilitado

Retorno:

NomeTipoDescrição
aRetCargaArray

Array de três posições, contendo:

  • aRetCarga[1] - aArrayCarga
  • aRetCarga[2] - aHeaders
  • aRetCarga[3] - bLine

Estes três elementos devem estar no mesmo formato em que foram recebidos por parâmetro; apenas com os campos adicionais que deverão ser apresentados na tela de Montagem de Carga.

Versões:12.1.17 ou superiores
Exemplo
#INCLUDE "PROTHEUS.CH"

#DEFINE CARGA_ENABLE    1
#DEFINE CARGA_COD       2
#DEFINE CARGA_DESC      3
#DEFINE CARGA_PESO      4
#DEFINE CARGA_VALOR     5
#DEFINE CARGA_VOLUM     6
#DEFINE CARGA_QTDLIB    7
#DEFINE CARGA_PTOENT    8
#DEFINE CARGA_TRANSP    9
#DEFINE CARGA_VEIC      10
#DEFINE CARGA_VEI2      11
#DEFINE CARGA_VEI3      12
#DEFINE CARGA_MOTOR     13
#DEFINE CARGA_AJUD1     14
#DEFINE CARGA_AJUD2     15
#DEFINE CARGA_AJUD3     16
#DEFINE CARGA_USER      27

User Function OM200AD2()
Local aRetCarga   := {}
Local oCargas     := PARAMIXB[1]
Local aArrayCarga := PARAMIXB[2]
Local aHeaders    := PARAMIXB[3]
Local bLine       := PARAMIXB[4]
Local oEnable     := PARAMIXB[5]
Local oDisable    := PARAMIXB[6]

    // Adiciona o título do campo a ser apresentado no array de Cabeçalhos
	aAdd(aHeaders,"Usuário")
	
	// Adiciona a informação que deve ser apresentada no campo
	aAdd(aArrayCarga[Len(aArrayCarga)],cUserName)

    // Inclui o campo no bloco de código para preenchimento das linhas do grid
	bLine:={ ||{Iif(aArrayCarga[oCargas:nAT,CARGA_ENABLE],oEnable,oDisable),;
    aArrayCarga[oCargas:nAT,CARGA_COD],;
    aArrayCarga[oCargas:nAT,CARGA_DESC],;
    aArrayCarga[oCargas:nAT,CARGA_PESO],;
    aArrayCarga[oCargas:nAT,CARGA_VALOR],;
    aArrayCarga[oCargas:nAT,CARGA_VOLUM],;
    aArrayCarga[oCargas:nAT,CARGA_QTDLIB],;
    aArrayCarga[oCargas:nAT,CARGA_PTOENT],;
    aArrayCarga[oCargas:nAT,CARGA_TRANSP],;
    aArrayCarga[oCargas:nAT,CARGA_VEIC],;
    aArrayCarga[oCargas:nAT,CARGA_VEI2],;
    aArrayCarga[oCargas:nAT,CARGA_VEI3],;
    aArrayCarga[oCargas:nAT,CARGA_MOTOR],;
    aArrayCarga[oCargas:nAT,CARGA_AJUD1],;
    aArrayCarga[oCargas:nAT,CARGA_AJUD2],;
    aArrayCarga[oCargas:nAT,CARGA_AJUD3],;
    aArrayCarga[oCargas:nAT,CARGA_USER]}}

    AAdd(aRetCarga, aArrayCarga)
    AAdd(aRetCarga, aHeaders)
    AAdd(aRetCarga, bLine)

Return aRetCarga