Linha Microsiga Protheus

Page tree

Pontos de Entrada MVC MATA020 na P12

Produto:

Protheus ADVPL

Versões:

P12

Ocorrência:

Pontos de entrada MVC MATA020 na P12

Ambiente:

P12

Passo a passo:

O id do modelo da dados da rotina MATA020 é CUSTOMERVENDOR, assim sendo, a assinatura da função de usuário deve ser User Function CUSTOMERVENDOR().

Obs.: O nome do arquivo.prw não poderá ser o mesmo da user function.


Exemplo:

#include "protheus.ch"
#include "parmtype.ch"

User Function CUSTOMERVENDOR()
    Local aParam := PARAMIXB
    Local xRet := .T.
    Local oObj := ""
    Local cIdPonto := ""
    Local cIdModel := ""
    Local lIsGrid := .F.
    Local nLinha := 0
    Local nQtdLinhas := 0
    Local cMsg := ""

    If aParam <> NIL
        oObj := aParam[1]
        cIdPonto := aParam[2]
        cIdModel := aParam[3]
        lIsGrid := (Len(aParam) > 3)

        If cIdPonto == "MODELPOS"
            cMsg := "Chamada na validação total do modelo." + CRLF
            cMsg += "ID " + cIdModel + CRLF

            xRet := ApMsgYesNo(cMsg + "Continua?")

        ElseIf cIdPonto == "FORMPOS"
            cMsg := "Chamada na validação total do formulário." + CRLF
            cMsg += "ID " + cIdModel + CRLF

            If lIsGrid
                cMsg += "É um FORMGRID com " + Alltrim(Str(nQtdLinhas)) + " linha(s)." + CRLF
                cMsg += "Posicionado na linha " + Alltrim(Str(nLinha)) + CRLF
            Else
                cMsg += "É um FORMFIELD" + CRLF
            EndIf

            xRet := ApMsgYesNo(cMsg + "Continua?")

        ElseIf cIdPonto == "FORMLINEPRE"
            If aParam[5] == "DELETE"
                cMsg := "Chamada na pré validação da linha do formulário. " + CRLF
                cMsg += "Onde esta se tentando deletar a linha" + CRLF
                cMsg += "ID " + cIdModel + CRLF
                cMsg += "É um FORMGRID com " + Alltrim(Str(nQtdLinhas)) + " linha(s)." + CRLF
                cMsg += "Posicionado na linha " + Alltrim(Str(nLinha)) + CRLF
                xRet := ApMsgYesNo(cMsg + " Continua?")
            EndIf

        ElseIf cIdPonto == "FORMLINEPOS"
            cMsg := "Chamada na validação da linha do formulário." + CRLF
            cMsg += "ID " + cIdModel + CRLF
            cMsg += "É um FORMGRID com " + Alltrim(Str(nQtdLinhas)) + " linha(s)." + CRLF
            cMsg += "Posicionado na linha " + Alltrim(Str(nLinha)) + CRLF
            xRet := ApMsgYesNo(cMsg + " Continua?")

        ElseIf cIdPonto == "MODELCOMMITTTS"
            ApMsgInfo("Chamada após a gravação total do modelo e dentro da transação.")

        ElseIf cIdPonto == "MODELCOMMITNTTS"
            ApMsgInfo("Chamada após a gravação total do modelo e fora da transação.")

        ElseIf cIdPonto == "FORMCOMMITTTSPRE"
            ApMsgInfo("Chamada após a gravação da tabela do formulário.")

        ElseIf cIdPonto == "FORMCOMMITTTSPOS"
            ApMsgInfo("Chamada após a gravação da tabela do formulário.")

        ElseIf cIdPonto == "MODELCANCEL"
            cMsg := "Deseja realmente sair?"
            xRet := ApMsgYesNo(cMsg)

        ElseIf cIdPonto == "BUTTONBAR"
            xRet := {{"Salvar", "SALVAR", {||u_TSMT020()}}}
        EndIf
    EndIf
Return xRet

User Function TSMT020()
    Alert("Buttonbar")
Return NIL

Mais detalhes:
Todos os pontos de entrada terão seu legado mantido, salvo os pontos que consideramos como pontos padrões (ex: validação após a gravação e botões que serão substituídos), os pontos que trazem conteúdo do sistema por PARAMIXB, esses serão mantidos com suas particularidades

Evidência:

http://tdn.totvs.com/download/attachments/317304617/teste_mvc_pe_mata020.rar?api=v2

Observações: