Tempo aproximado para leitura: 05 min
01. DADOS GERAIS
| Linha de Produto: | Microsiga Protheus® |
|---|---|
| Segmento: | Jurídico |
| Módulo: | Pré-faturamento de Serviços - SIGAPFS |
| Função: | Emissão de Pré-Faturas - JURA201 Emissão de Faturas - JURA203 |
| Descrição: | Ponto de entrada para atribuir uma cotação específica no faturamento das despesas. | |||||||||||||||||||||||
|---|---|---|---|---|---|---|---|---|---|---|---|---|---|---|---|---|---|---|---|---|---|---|---|---|
Localização: | Atualizações >> Movimentações >> Emissão de Fatura | |||||||||||||||||||||||
Programa Fonte: | JURA201 e JURA203 | |||||||||||||||||||||||
Função: | JA201DCaso e J203HSumDP | |||||||||||||||||||||||
| Ponto de Entrada: | JURCOTDP | |||||||||||||||||||||||
| Parâmetros: |
| |||||||||||||||||||||||
| Retorno: |
|
Importante!
1. Caso a moeda da(s) despesa(s) e da fatura forem diferentes da moeda nacional, é necessário retornar o fator entre elas (cotação da moeda da despesa dividida pela cotação da moeda da fatura), conforme exemplo no ponto de entrada.
2. Os relatórios de faturamento imprimem o valor da taxa da cotação padrão do sistema, para exibir o valor da taxa de cotação utilizada no ponto de entrada JURCOTDP, será preciso customizar.
#INCLUDE "PROTHEUS.CH"
//-------------------------------------------------------------------
/*/{Protheus.doc} JURCOTDP
Ponto de entrada para informar uma cotação específica no faturamento
das despesas.
@param PARAMIXB, array , Parâmetros do ponto de entradas
PARAMIXB[1], caracter , Código da despesa
PARAMIXB[2], caracter , Moeda da despesa
PARAMIXB[3], caracter , Moeda do Faturamento
PARAMIXB[4], caracter , Se o conteúdo for igual a "1" é Emissão de Pré-fatura,
mas se o conteúdo for igual a "2" a emissão é de Fatura.
@return nCotDesp, numérico, Deve retornar o valor da cotação para uso no faturamento da despesa.
Se o valor do retorno da for igual a 0 será aplicada a cotação com
a regra padrão do sistema que considera o parâmetro MV_JCONVDS.
@author TOTVS
@since 21/08/2024
@Obs Ponto de entrada executado na emissão de Pré-Fatura e Fatura.
/*/
//-------------------------------------------------------------------
User Function JURCOTDP()
Local cMoeDesp := PARAMIXB[2]
Local cMoeFat := PARAMIXB[3]
Local cMoeNac := SuperGetMv('MV_JMOENAC',, '01' )
Local nCotDesp := 0
Local nCotDolar := 6 // Cotação do dólar
Local nCotEuro := 12 // Cotação do euro
Do Case
// Quando são utilizadas 2 moedas estrangeiras (moeda da despesa e da fatura), o ponto de entrada deverá retornar o fator entre elas.
Case cMoeDesp != cMoeNac .And. cMoeFat != cMoeNac .And. cMoeDesp != cMoeFat
If cMoeDesp == "02" .And. cMoeFat == "03" // Moeda da despesa está em Dólar e da fatura está em Euro
nCotDesp := nCotDolar/nCotEuro
ElseIf cMoeDesp == "03" .And. cMoeFat == "02" // Moeda da despesa está em Euro e da fatura está em Dólar
nCotDesp := nCotEuro/nCotDolar
EndIf
Case cMoeDesp == "02" .Or. cMoeFat == "02" // Dólar
nCotDesp := nCotDolar
Case cMoeDesp == "03" .Or. cMoeFat == "03" // Euro
nCotDesp := nCotEuro
End Case
Return nCotDesp