Alteração do workflow de Ordens de Serviço Liberadas

Características do Requisito

Linha de Produto:

Microsiga Protheus

Segmento:

Manufatura

Módulo:

SIGAMNT - Manutenção de Ativos e Gestão de Frotas

Rotina:

Rotina

Nome Técnico

MNTW215

Programa para exportar dados para gerar workflow com alerta de

Ordem de Serviço Liberada

Rotina(s) envolvida(s)	Nome Técnico
MNTW215	Programa para exportar dados para gerar workflow com alerta de Ordem de Serviço Liberada
MNTA275	Confirmação O.S. Execução
MNTA295	Distribuição S.S.
MNTA340	Confirmação de Serviço de Manutenção
MNTA365	Substituição de O.S.
MNTA410	Ordem de Serviço
MNTA420	O.S. Corretiva
MNTA430	Histórico O.S.
MNTA490	Liberação de O.S.
MNTA990	Programação de Ordem de Serviço

Chamados Relacionados

V127 TVSSPY

País(es):

Todos

Banco(s) de Dados:

Todos

Sistema(s) Operacional(is):

Todos

Ponto de Entrada

Descrição:

Ponto de Entrada que alteração do layout do workflow de envio de alerta de O.S. liberada.

Eventos:

Workflow (MNTW215)

Programa Fonte:

MNTW215.PRW

Função:

MNTW2151()

Retorno:

Nome	Tipo	Descrição	Obrigatório
cBody	caracter	HTML do workflow	Sim

Exemplo:

#Include 'Protheus.ch'

User Function MNTW2151()

Local cBody := ParamIXB[1]

Local n

Local cPlano

Local cOrdem

Local cCodBem

Local cNomBem

Local cServico

Local cNomSer

Local cCCusto

Local cNCusto

Local cPriorid

Local cDtPrev

Local cHrPrev

Local aInsumos := {}

dbSelectArea("STJ")

cPlano := STJ->TJ_PLANO

cOrdem := STJ->TJ_ORDEM

cCodBem := STJ->TJ_CODBEM

cNomBem := If(STJ->TJ_TIPOOS = "B",Posicione("ST9",1,xFilial("ST9")+STJ->TJ_CODBEM,"T9_NOME"),;

Posicione("TAF",7,xFilial("TAF")+"X2"+Substr(STJ->TJ_CODBEM,1,3),"TAF_NOMNIV"))

cServico := STJ->TJ_SERVICO

cNomSer := Posicione("ST4",1,xFilial("ST4")+STJ->TJ_SERVICO,'T4_NOME')

cCCusto := STJ->TJ_CCUSTO

cNCusto := Posicione("CTT",1,xFilial("CTT")+STJ->TJ_CCUSTO,'CTT_DESC01')

cPriorid := STJ->TJ_PRIORID

cDtPrev := STJ->TJ_DTMPINI

cHrPrev := STJ->TJ_HOMPINI

dbSelectArea("STL")

dbSetOrder(1)

dbSeek(xFilial("STL")+cOrdem+cPlano)

While !Eof() .And. STL->TL_ORDEM == cOrdem .And. cPlano == STL->TL_PLANO

aAdd(aInsumos,{STL->TL_CODIGO, STL->TL_TIPOREG, STL->TL_QUANTID, STL->TL_UNIDADE,;

STL->TL_SEQRELA, STL->TL_DTINICI, STL->TL_HOINICI, STL->TL_DTFIM, STL->TL_HOFIM})

dbSkip()

EndDo

//----Workflow padrão----

cBody := '<html>'

cBody += ' <head>'

cBody += ' <meta http-equiv="Content-Language" content="pt-br">'

cBody += ' <meta http-equiv="Content-Type" content="text/html; charset=windows-1252">'

cBody += ' <meta name="GENERATOR" content="Microsoft FrontPage 4.0">'

cBody += ' <meta name="ProgId" content="FrontPage.Editor.Document">'

cBody += ' <title>Aviso sobre Solicitaçãoo de Serviços</title>'

cBody += ' </head>'

cBody += ' <body bgcolor="#FFFFFF">'

cBody += ' <noscript>'

cBody += ' </noscript>'

cBody += ' '+"O.S. Liberada"+''

cBody += ' <table border=0 WIDTH=100% cellpadding="1">'

cBody += ' <tr>'

cBody += ' <td bgcolor="#C0C0C0" align="left">'+"Ordem"+'</td>'

cBody += ' <td bgcolor="#C0C0C0" align="left">'+"Plano"+'</td>'

cBody += ' <td bgcolor="#C0C0C0" align="left">'+"Bem"+'</td>'

cBody += ' <td bgcolor="#C0C0C0" align="left">'+"Descrição"+'</td>'

cBody += ' <td bgcolor="#C0C0C0" align="left">'+"Serviço"+'</td>'

cBody += ' <td bgcolor="#C0C0C0" align="left">'+"Descrição"+'</td>'

cBody += ' <td bgcolor="#C0C0C0" align="left">'+"Centro de Custo"+'</td>'

cBody += ' <td bgcolor="#C0C0C0" align="left">'+"Descrição"+'</td>'

cBody += ' <td bgcolor="#C0C0C0" align="left">'+"Prioridade"+'</td>'

cBody += ' <td bgcolor="#C0C0C0" align="center">'+"Data Prev. Início"+'</td>'

cBody += ' <td bgcolor="#C0C0C0" align="center">'+"Hora Prev. Início"+'</td>'

cBody += ' </tr>'

cBody += ' <tr>'

cBody += ' <td bgcolor="#EEEEEE" align="left">'+cOrdem+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="left">'+cPlano+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="left">'+cCodBem+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="left">'+cNomBem+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="left">'+cServico+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="left">'+cNomSer+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="left">'+cCCusto+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="left">'+cNCusto+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="left">'+cPriorid+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="center">'+DToC(cDtPrev)+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="center">'+cValToChar(cHrPrev)+'</td>'

cBody += ' </tr>'

cBody += ' </table>'

//----Inicio-Customização----

cBody += ' Insumos Previstos'

cBody += ' <Table>'

cBody += ' <tr>'

cBody += ' <td bgcolor="#C0C0C0" align="left">Codigo</td>'

cBody += ' <td bgcolor="#C0C0C0" align="left">Tipo</td>'

cBody += ' <td bgcolor="#C0C0C0" align="left">Quant. Utiliz.</td>'

cBody += ' <td bgcolor="#C0C0C0" align="left">Unidade</td>'

cBody += ' <td bgcolor="#C0C0C0" align="left">Sequência</td>'

cBody += ' <td bgcolor="#C0C0C0" align="left">Dt. Inicio</td>'

cBody += ' <td bgcolor="#C0C0C0" align="left">Hr. Inicio</td>'

cBody += ' <td bgcolor="#C0C0C0" align="left">Dt. Fim</td>'

cBody += ' <td bgcolor="#C0C0C0" align="left">Hr. Fim</td>'

cBody += ' </tr>'

For n := 1 To Len(aInsumos)

cBody += ' <tr>'

cBody += ' <td bgcolor="#EEEEEE" align="left">'+aInsumos[n,1]+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="center">'+aInsumos[n,2]+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="right">'+cValToChar(aInsumos[n,3])+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="center">'+aInsumos[n,4]+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="right">'+aInsumos[n,5]+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="center">'+DtoC(aInsumos[n,6])+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="center">'+cValToChar(aInsumos[n,7])+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="center">'+DtoC(aInsumos[n,8])+'</td>'

cBody += ' <td bgcolor="#EEEEEE" align="center">'+cValToChar(aInsumos[n,9])+'</td>'

cBody += ' </tr>'

Next n

//-------Fim-Customização----

cBody += ' </table>'

cBody += ' <hr>'

cBody += ' </body>'

cBody += '</html>'

Return cBody

Page tree

DT PE MNTW2151 Altera Workflow OS Liberada

Alteração do workflow de Ordens de Serviço Liberadas

Características do Requisito

Ponto de Entrada