Adiciona uma coluna na tabela de detalhes do monitor.
Parâmetros
| Nome | Tipo | Descrição | Referência |
|---|---|---|---|
| aColunas | Array | Array que receberá o conteúdo das colunas. | X |
| nIndice | Numérico | Indice para a posição ser adicionada no array. | X |
| cProp | Caracter | Código da coluna. | |
| cTexto | Caracter | Nome da coluna. | |
| cTipo | Caracter | Tipo da coluna. | |
| lVisivel | Lógico | Indica se a coluna será visível por padrão. | |
| lTipoLabel | Lógico | Indica se a coluna é do tipo 'label'. | |
| aLabels | Array | Array com as legendas da coluna tipo 'label'. |
Exemplo de Uso
Method BuscaDetalhes(oFiltros, nPagina) Class StatusOrdemProducao
Local aColunas := {}
Local aLabels := {}
Local cJsonDados := ""
Local lExpResult := .F.
Local nIndCols := 0
Local nIndLabels := 0
Local nPos := 0
Local oDados := JsonObject():New()
oDados["items"] := {}
oDados["columns"] := {}
oDados["headers"] := {}
oDados["tags"] := {}
oDados["canExportCSV"] := .T.
oDados["hasNext"] := .F.
If nPagina == 0
lExpResult := .T.
EndIf
PCPMonitorUtils():AdicionaLabelsColunaTabela(aLabels,@nIndLabels,"1","rgba(255,255,0,1)","Prevista","rgba(0,0,0,1)")
PCPMonitorUtils():AdicionaLabelsColunaTabela(aLabels,@nIndLabels,"2","rgba(126,226,148,1)","Em aberto","rgba(255,255,255,1)")
PCPMonitorUtils():AdicionaLabelsColunaTabela(aLabels,@nIndLabels,"3","rgba(255,128,0,1)","Iniciada","rgba(255,255,255,1)")
PCPMonitorUtils():AdicionaLabelsColunaTabela(aLabels,@nIndLabels,"4","rgba(128,128,128,1)","Ociosa","rgba(255,255,255,1)")
PCPMonitorUtils():AdicionaLabelsColunaTabela(aLabels,@nIndLabels,"5","rgba(0,0,165,1)","Enc.Parcialmente","rgba(255,255,255,1)")
PCPMonitorUtils():AdicionaLabelsColunaTabela(aLabels,@nIndLabels,"6","rgba(241,143,136,1)","Enc.Totalmente","rgba(255,255,255,1)")
PCPMonitorUtils():AdicionaColunaTabela(aColunas,@nIndCols,"STATUS","Status","cellTemplate",.T.,.T.,aLabels)
PCPMonitorUtils():AdicionaColunaTabela(aColunas,@nIndCols,"C2_FILIAL","Filial","string",lExpResult)
PCPMonitorUtils():AdicionaColunaTabela(aColunas,@nIndCols,"C2_OP","OP","string",.T.)
PCPMonitorUtils():AdicionaColunaTabela(aColunas,@nIndCols,"C2_PRODUTO","Produto","string",.T.)
PCPMonitorUtils():AdicionaColunaTabela(aColunas,@nIndCols,"B1_DESC","Desc. Produto","string",lExpResult)
PCPMonitorUtils():AdicionaColunaTabela(aColunas,@nIndCols,"C2_LOCAL","Armazém","string",.T.)
PCPMonitorUtils():AdicionaColunaTabela(aColunas,@nIndCols,"C2_DATPRI","Previsão Início","date",.T.)
PCPMonitorUtils():AdicionaColunaTabela(aColunas,@nIndCols,"C2_DATPRF","Previsão Entrega","date",.T.)
PCPMonitorUtils():AdicionaColunaTabela(aColunas,@nIndCols,"C2_QUANT","Quantidade","number",.T.)
PCPMonitorUtils():AdicionaColunaTabela(aColunas,@nIndCols,"C2_QUJE","Qtd. Prod","number",.T.)
oDados["columns"] := aClone(aColunas)
aAdd(oDados["items"], JsonObject():New())
nPos++
oDados["items"][nPos]["STATUS"] := "3"
oDados["items"][nPos]["C2_FILIAL"] := "01"
oDados["items"][nPos]["C2_OP"] := "00000101001"
oDados["items"][nPos]["C2_PRODUTO"] := "CANETA"
oDados["items"][nPos]["B1_DESC"] := "PRODUTO CANETA"
oDados["items"][nPos]["C2_LOCAL"] := "01"
oDados["items"][nPos]["C2_DATPRI"] := "2023-11-03"
oDados["items"][nPos]["C2_DATPRF"] := "2023-11-06"
oDados["items"][nPos]["C2_QUANT"] := 100
oDados["items"][nPos]["C2_QUJE"] := 20
cJsonDados := oDados:toJson()
FreeObj(oDados)
FwFreeArray(aColunas)
FwFreeArray(aLabels)
Return cJsonDados