Método construtor da classe.
TSay():New( [ nRow ], [ nCol ], [ bText ], [ oWnd ], [ cPicture ], [ oFont ], [ uParam7 ], [ uParam8 ], [ uParam9 ], [ lPixels ], [ nClrText ], [ nClrBack ], [ nWidth ], [ nHeight ], [ uParam15 ], [ uParam16 ], [ uParam17 ], [ uParam18 ], [ uParam19 ], [ lHTML ], [ nTxtAlgHor ], [ nTxtAlgVer ] )
Nome | Tipo | Descrição | Obrigatório | Referência |
|---|---|---|---|---|
nRow | numérico | Indica a coordenada vertical em pixels ou caracteres. | ||
nCol | numérico | Indica a coordenada horizontal em pixels ou caracteres. | ||
bText | bloco de código | Indica o bloco de código que será executado para retornar e apresentar uma string. | ||
oWnd | objeto | Indica a janela ou controle visual onde o objeto será criado. | ||
cPicture | caractere | Indica a máscara de formatação, do conteúdo, que será apresentada. Verificar Tabela de Pictures de Formatação. | ||
oFont | objeto | Indica o objeto do tipo TFont utilizado para definir as características da fonte aplicada na exibição do conteúdo do controle visual. | ||
uParam7 | lógico | Compatibilidade. | ||
uParam8 | lógico | Compatibilidade. | ||
uParam9 | lógico | Compatibilidade. | ||
lPixels | lógico | Indica se considera as coordenadas passadas em pixels (.T.) ou caracteres (.F.). | ||
nClrText | numérico | Indica a cor do texto do objeto. | ||
nClrBack | numérico | Indica a cor de fundo do objeto. | ||
nWidth | numérico | Indica a largura em pixels do objeto. | ||
nHeight | numérico | Indica a altura em pixels do objeto. | ||
uParam15 | lógico | Compatibilidade. | ||
uParam16 | lógico | Compatibilidade. | ||
uParam17 | lógico | Compatibilidade. | ||
uParam18 | lógico | Compatibilidade. | ||
uParam19 | lógico | Compatibilidade. | ||
lHTML | lógico | Indica se, verdadeiro (.T.), habilita a visualização do texto no formato HTML; caso contrário, falso (.F.). | ||
nTxtAlgHor | numérico | Alinhamento horizontal do texto (Consulte tabela na página do método SetTextAlign). Disponível a partir da versão 17.3.0.0. | ||
nTxtAlgVer | numérico | Alinhamento vertical do texto (Consulte tabela na página do método SetTextAlign). Disponível a partir da versão 17.3.0.0. |
Nome | Tipo | Descrição |
|---|---|---|
oObj | objeto | Nova instância da classe TSay |
oSay:= TSay():New(01,01,{||'Texto para exibição'},oDlg,,oFont,,,,.T.,CLR_RED,CLR_WHITE,200,20)
// utilizando HTML na classe TSay
#Include "TOTVS.CH"
User Function TSayHtml()
DEFINE DIALOG oDlg TITLE "Exemplo TSay com HTML" FROM 180,180 TO 650,800 PIXEL
// Cria fonte para ser usada no TSay
oFont := TFont():New('Courier new',,-18,.T.)
// Monta o Texto no formato HTML
cTextHtml := '<hr size="1">'+;
'<font size="1" color="red">Linha 01 Red</font><br/>'+;
'<font size="2" color="green">Linha 02 Green</font><br/>'+;
'<font size="3" color="pink">Linha 03 Pink</font><br/>'+;
'<font size="4" color="blue">Linha 04 Blue</font><br/>'+;
'<font size="5" color="black">Linha 05 black</font><br/>'+;
'<label>Html label1 </label>'+;
'<label>Html Label2 </label>'+;
'<p>Html parágrafo1 </p>'+;
'<h5>Html header H5 </h5><br/>'+;
'<table border="1" cellpadding="1" cellspacing="0">'+;
'<tr>'+;
'<td width="100" bgcolor="#FFFF87">Coluna 01a</td>'+;
'<td width="200" bgcolor="#FFFF87">Coluna 02a</td>'+;
'<td width="100" bgcolor="#FFFF87">Coluna 03a</td>'+;
'</tr>'+;
'<tr>'+;
'<td>Coluna 01b</td>'+;
'<td>Coluna 02b</td>'+;
'<td>Coluna 03b</td>'+;
'</tr>'+;
'<tr>'+;
'<td>Coluna 01c</td>'+;
'<td>Coluna 02c</td>'+;
'<td>Coluna 03c</td>'+;
'</tr>'+;
'</table>'
// Cria o TSay permitindo texto no formato HMTL
lHtml := .T.
oSay := TSay():New(01,01,{||cTextHtml},oDlg,,oFont,,,,.T.,,,400,300,,,,,,lHtml)
ACTIVATE DIALOG oDlg CENTERED
Return
A construção de um componente da classe TSAY() pelo construtor NEW() também pode ser feita através do comando AdvPL @ .. SAY