Descrição: | O ponto de entrada AF060TOK que valida os dados inseridos antes da gravação na rotina Transferência de Ativos (ATFA060). |
Localização: | Movimentos/Transferência |
Eventos: | lAux := ExecBlock("AF060TOK",.F.,.F.,{oModel}) |
Programa Fonte: | ATFA060.PRW |
| Parâmetros | oModel : Modelo de dados corrente. |
Função: | Informe o Nome do(s) produto(s) a ser utilizado ou “Todos” |
| Retorno | lAux : Lógico |
Exemplo:
#Include "PROTHEUS.CH"
#include "FWMVCDEF.CH"
User function AF060TOK()
Local aArea := GetArea()
Local oModel := ParamIXB[1]
Local oAtivo := Nil
Local oSaldo := Nil
Local aSaveLine := {}
Local nLinAtivo := 0
Local nLinSaldo := 0
//Dados do bem
Local dDataTrans := SToD("")
Local cFilDest := ""
Local cFilOrig := ""
Local cBem := ""
Local cItem := ""
//Dados do tipo de saldo
Local cTipoSld := ""
Local cCorrMonet := ""
Local cDespDepr := ""
Local cDeprAcum := ""
Local cCorMonDep := ""
Local lAux := .T.
//Obtem o submodelo.
oAtivo := oModel:GetModel("GridFNR")
oSaldo := oModel:GetModel("GridFNS")
//Guarda a posição das linhas
aSaveLine := FwSaveRows()
//Efetua laço nos bens a serem transferidos
For nLinAtivo := 1 to oAtivo:Length()
oAtivo:GoLine(nLinAtivo)
cFilDest := oAtivo:GetValue("FNR_FILDES")
cFilOrig := oAtivo:GetValue("FNR_FILIAL")
dDataTrans := oAtivo:GetValue("FNR_DATA")
cBem := oAtivo:GetValue("FNR_CBAORI")
cItem := oAtivo:GetValue("FNR_ITEORI")
//Efetua laço nos saldos do bem posicionado
For nLinSaldo := 1 To oSaldo:Length()
oSaldo:GoLine(nLinSaldo)
cTipoSld := oSaldo:GetValue("FNS_TIPO")
cCorrMonet := oSaldo:GetValue("FNS_CONCOO")
cDespDepr := oSaldo:GetValue("FNS_CONDDO")
cDeprAcum := oSaldo:GetValue("FNS_CONDAO")
cCorMonDep := oSaldo:GetValue("FNS_CONCDO")
MsgAlert("Conta Contábil" + CRLF + "Codigo Base de Origem : " + cBem;
+ " Item do ativo de origem : " + cItem + " Tipo Saldo: " + cTipoSld;
+ CRLF + "Conta Corr. Monet. Orig. : " + cCorrMonet;
+ CRLF + "Conta Desp. Deprec. Orig. : " + cDespDepr;
+ CRLF + "Conta Deprec Acumul Orig. : " + cDeprAcum;
+ CRLF + "Conta Corr. Deprec. Orig. : " + cCorMonDep,'PE AF060TOK')
Next nLinSaldo
Next nLinAtivo
//Restaura a posição das linhas
FwRestRows(aSaveLine)
RestArea(aArea)
Return lAux
